blob: 6fd64bafb9893287e07b2608bbdeab79fa670c35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
KDE_HANDBOOK="forceoptional"
PYTHON_COMPAT=( python2_7 )
inherit kde5 python-single-r1
if [[ ${KDE_BUILD_TYPE} = release ]]; then
SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
KEYWORDS="amd64 x86"
fi
DESCRIPTION="Desktop Planetarium"
HOMEPAGE="https://www.kde.org/applications/education/kstars https://edu.kde.org/kstars/"
IUSE="fits indi +password raw wcs"
REQUIRED_USE="indi? ( fits ) ${PYTHON_REQUIRED_USE}"
COMMON_DEPEND="
$(add_frameworks_dep kauth)
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep kcrash)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kio)
$(add_frameworks_dep knewstuff)
$(add_frameworks_dep knotifications)
$(add_frameworks_dep knotifyconfig)
$(add_frameworks_dep kplotting)
$(add_frameworks_dep kwidgetsaddons)
$(add_frameworks_dep kxmlgui)
$(add_qt_dep qtdatavis3d)
$(add_qt_dep qtdbus)
$(add_qt_dep qtdeclarative)
$(add_qt_dep qtgui)
$(add_qt_dep qtnetwork)
$(add_qt_dep qtprintsupport)
$(add_qt_dep qtsql)
$(add_qt_dep qtsvg)
$(add_qt_dep qtwebsockets)
$(add_qt_dep qtwidgets)
sys-libs/zlib
fits? ( sci-libs/cfitsio )
indi? ( >=sci-libs/indilib-1.7.5 )
password? ( dev-libs/qtkeychain:= )
raw? ( media-libs/libraw:= )
wcs? ( sci-astronomy/wcslib )
"
# TODO: Add back when re-enabled by upstream
# opengl? (
# $(add_qt_dep qtopengl)
# virtual/opengl
# )
DEPEND="${COMMON_DEPEND}
$(add_qt_dep qtconcurrent)
dev-cpp/eigen:3
"
RDEPEND="${COMMON_DEPEND}
${PYTHON_DEPS}
"
src_configure() {
local mycmakeargs=(
-DFETCH_TRANSLATIONS=OFF
$(cmake-utils_use_find_package fits CFitsio)
$(cmake-utils_use_find_package indi INDI)
$(cmake-utils_use_find_package password Qt5Keychain)
$(cmake-utils_use_find_package raw LibRaw)
$(cmake-utils_use_find_package wcs WCSLIB)
)
kde5_src_configure
}
pkg_postinst () {
kde5_pkg_postinst
if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "x11-misc/xplanet" ; then
elog "${PN} has optional runtime support for x11-misc/xplanet"
fi
# same for AstrometryNet, which is not packaged.
}
|
GitWeb