1 files changed, 0 insertions, 61 deletions
diff --git a/dev-util/ccache/ccache-3.4.2.ebuild b/dev-util/ccache/ccache-3.4.2.ebuild
deleted file mode 100644
index 41543471..00000000
--- a/dev-util/ccache/ccache-3.4.2.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit readme.gentoo-r1
-
-DESCRIPTION="fast compiler cache"
-HOMEPAGE="https://ccache.samba.org/"
-SRC_URI="https://www.samba.org/ftp/ccache/${P}.tar.xz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd"
-IUSE=""
-
-DEPEND="app-arch/xz-utils
-	sys-libs/zlib"
-RDEPEND="${DEPEND}
-	dev-util/shadowman
-	sys-apps/gentoo-functions"
-
-src_prepare() {
-	# make sure we always use system zlib
-	rm -rf zlib || die
-	default
-}
-
-src_install() {
-	default
-
-	insinto /usr/share/shadowman/tools
-	newins - ccache <<<'/usr/lib/ccache/bin'
-
-	DOC_CONTENTS="
-To use ccache with **non-Portage** C compiling, add
-${EPREFIX}/usr/lib/ccache/bin to the beginning of your path, before ${EPREFIX}/usr/bin.
-Portage 2.0.46-r11+ will automatically take advantage of ccache with
-no additional steps.  If this is your first install of ccache, type
-something like this to set a maximum cache size of 2GB:\\n
-# ccache -M 2G\\n
-If you are upgrading from an older version than 3.x you should clear all of your caches like so:\\n
-# CCACHE_DIR='${CCACHE_DIR:-${PORTAGE_TMPDIR}/ccache}' ccache -C\\n
-ccache now supports sys-devel/clang and dev-lang/icc, too!"
-
-	readme.gentoo_create_doc
-}
-
-pkg_prerm() {
-	[ -n "${REPLACED_BY_VERSION}${ROOT}" ] || \
-		eselect compiler-shadow remove ccache
-}
-
-pkg_postinst() {
-	[ -n "${ROOT}" ] || eselect compiler-shadow update ccache
-
-	# nuke broken symlinks from previous versions that shouldn't exist
-	rm -rf "${EROOT}"/usr/lib/ccache.backup || die
-
-	readme.gentoo_print_elog
-}