Version bump. Fix pam.d file - bug #261687. Add berkdb USE

flag - bug #322207.

(Portage version: 2.1.10.3/cvs/Linux x86_64)

2 files changed, 71 insertions, 2 deletions

diff --git a/net-mail/perdition/ChangeLog b/net-mail/perdition/ChangeLog
index f0dd3551e600..7117d42490ae 100644
--- a/net-mail/perdition/ChangeLog
+++ b/net-mail/perdition/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-mail/perdition
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/perdition/ChangeLog,v 1.12 2010/06/17 21:54:54 patrick Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-mail/perdition/ChangeLog,v 1.13 2011/06/15 14:44:11 eras Exp $
+
+*perdition-1.18 (15 Jun 2011)
+
+  15 Jun 2011; Eray Aslan <eras@gentoo.org> +perdition-1.18.ebuild:
+  Version bump. Fix pam.d file - bug #261687. Add berkdb USE flag - bug
+  #322207.
 
   17 Jun 2010; Patrick Lauer <patrick@gentoo.org> perdition-1.17.1.ebuild:
   Migrating away from deprecated postgres virtuals
diff --git a/net-mail/perdition/perdition-1.18.ebuild b/net-mail/perdition/perdition-1.18.ebuild
new file mode 100644
index 000000000000..534466efa2d1
--- /dev/null
+++ b/net-mail/perdition/perdition-1.18.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-mail/perdition/perdition-1.18.ebuild,v 1.1 2011/06/15 14:44:11 eras Exp $
+
+EAPI=4
+inherit eutils pam
+
+DESCRIPTION="modular and fully featured POP3 and IMAP4 proxy"
+HOMEPAGE="http://www.vergenet.net/linux/perdition/"
+SRC_URI="http://www.vergenet.net/linux/${PN}/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="berkdb cdb ssl mysql odbc postgres gdbm ldap"
+
+DEPEND="dev-scheme/guile
+	>=dev-libs/vanessa-logger-0.0.8
+	>=dev-libs/vanessa-adt-0.0.6
+	>=net-libs/vanessa-socket-0.0.10
+	dev-libs/libpcre
+	virtual/pam
+	berkdb? ( sys-libs/db )
+	cdb? ( || ( >=dev-db/tinycdb-0.76 >=dev-db/cdb-0.75-r1 ) )
+	ssl? ( dev-libs/openssl )
+	odbc? ( dev-db/unixODBC )
+	gdbm? ( sys-libs/gdbm )
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql-server )
+	ldap? ( net-nds/openldap )"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	enewuser perdition
+}
+
+src_configure() {
+	econf --with-user=perdition \
+		--enable-posix-regex \
+		$(use_enable ssl) \
+		$(use_enable mysql) \
+		$(use_enable odbc) \
+		$(use_enable postgres pg) \
+		$(use_enable gdbm) \
+		$(use_enable ldap) \
+		$(use_enable cdb) \
+		$(use_enable berkdb bdb)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc README AUTHORS TODO INSTALL ChangeLog CODING_LOCATIONS
+
+	newinitd "${FILESDIR}"/perdition.initd perdition
+	newconfd "${FILESDIR}"/perdition.confd perdition
+
+	rm -f "${D}"/etc/pam.d/perdition
+	pamd_mimic sys-auth perdition auth account password session
+
+	keepdir /var/run/perdition
+	chown perdition "${D}"/var/run/perdition
+}