Version bump.

(Portage version: 2.2_rc1/cvs/Linux 2.6.25-gentoo-r5 x86_64)

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-java/commons-collections/commons-collections-3.2.1.ebuild b/dev-java/commons-collections/commons-collections-3.2.1.ebuild
new file mode 100644
index 000000000000..2466de362770
--- /dev/null
+++ b/dev-java/commons-collections/commons-collections-3.2.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-collections/commons-collections-3.2.1.ebuild,v 1.1 2008/06/21 17:36:41 fordfrog Exp $
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2 eutils
+
+DESCRIPTION="Jakarta-Commons Collections Component"
+HOMEPAGE="http://jakarta.apache.org/commons/collections/"
+SRC_URI="mirror://apache/jakarta/${PN/-//}/source/${P}-src.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="test-framework"
+
+COMMON_DEP="test-framework? ( =dev-java/junit-3.8* )"
+DEPEND=">=virtual/jdk-1.4
+	test? ( dev-java/ant-junit )
+	${COMMON_DEP}"
+RDEPEND=">=virtual/jre-1.4
+	${COMMON_DEP}"
+
+S="${WORKDIR}/${P}-src"
+
+src_compile() {
+	local antflags
+	if use test-framework; then
+		antflags="tf.jar -Djunit.jar=$(java-pkg_getjars junit)"
+		#no support for installing two sets of javadocs via dojavadoc atm
+		#use doc && antflags="${antflags} tf.javadoc"
+	fi
+	eant jar $(use_doc) ${antflags}
+}
+
+src_test() {
+	if [[ "${ARCH}" = "ppc" ]]; then
+		einfo "Tests are disabled on ppc"
+	else
+		ANT_TASKS="ant-junit" eant testjar -Djunit.jar="$(java-pkg_getjars junit)"
+	fi
+}
+
+src_install() {
+	java-pkg_newjar build/${P}.jar ${PN}.jar
+	use test-framework && \
+		java-pkg_newjar build/${PN}-testframework-3.2.jar \
+			${PN}-testframework.jar
+
+	dodoc README.txt || die
+	java-pkg_dohtml *.html || die
+	if use doc; then
+		java-pkg_dojavadoc build/docs/apidocs
+		#use test-framework && java-pkg_dojavadoc build/docs/testframework
+	fi
+	use source && java-pkg_dosrc src/java/*
+}