Add missing gnome-python dep (monolithic for stable and bump to -r1 for dep on split ebuilds (gnome-vfs and libgnome)

(Portage version: 2.2_rc8/cvs/Linux 2.6.26.2 i686)

3 files changed, 98 insertions, 2 deletions

diff --git a/app-editors/gedit/ChangeLog b/app-editors/gedit/ChangeLog
index 23228a696997..e5e14e927562 100644
--- a/app-editors/gedit/ChangeLog
+++ b/app-editors/gedit/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-editors/gedit
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.248 2008/08/17 19:27:03 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.249 2008/09/15 03:52:40 ford_prefect Exp $
+
+*gedit-2.22.3-r1 (15 Sep 2008)
+
+  15 Sep 2008; Arun Raghavan <ford_prefect@gentoo.org> gedit-2.22.3.ebuild,
+  +gedit-2.22.3-r1.ebuild:
+  Add missing gnome-python dep (monolithic for stable and bump to -r1 for
+  dep on split ebuilds (gnome-vfs and libgnome)
 
   17 Aug 2008; Arun Raghavan <ford_prefect@gentoo.org> gedit-2.22.3.ebuild:
   Add gtk-doc dep for USE=doc
diff --git a/app-editors/gedit/gedit-2.22.3-r1.ebuild b/app-editors/gedit/gedit-2.22.3-r1.ebuild
new file mode 100644
index 000000000000..f7f6af98fdc6
--- /dev/null
+++ b/app-editors/gedit/gedit-2.22.3-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.22.3-r1.ebuild,v 1.1 2008/09/15 03:52:40 ford_prefect Exp $
+
+inherit gnome2 python eutils autotools
+
+DESCRIPTION="A text editor for the GNOME desktop"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc python spell xattr"
+
+RDEPEND=">=gnome-base/gconf-2
+	xattr? ( sys-apps/attr )
+	>=dev-libs/glib-2.14
+	>=x11-libs/gtk+-2.12
+	>=x11-libs/gtksourceview-2.2
+	>=gnome-base/libgnomeui-2.16
+	>=gnome-base/libglade-2.5.1
+	>=gnome-base/gnome-vfs-2.16
+	spell? (
+		>=app-text/enchant-1.2
+		app-text/iso-codes
+	)
+	python? (
+		>=dev-python/pygobject-2.12
+		>=dev-python/pygtk-2.12
+		>=dev-python/pygtksourceview-2.2
+		>=dev-python/gnome-vfs-python-2.22.1
+		>=dev-python/libgnome-python-2.22.1
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/pkgconfig-0.9
+	>=app-text/scrollkeeper-0.3.11
+	>=dev-util/intltool-0.35
+	>=app-text/gnome-doc-utils-0.3.2
+	gnome-base/gnome-common
+	doc? ( dev-util/gtk-doc )"
+# gnome-common needed to eautoreconf
+
+DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"
+
+if [[ "${ARCH}" == "PPC" ]] ; then
+	# HACK HACK HACK: someone fix this garbage
+	MAKEOPTS="${MAKEOPTS} -j1"
+fi
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		$(use_enable python)
+		$(use_enable spell)
+		$(use_enable xattr attr)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Remove symbols that are not meant to be part of the docs, and
+	# break compilation if USE="doc -python" (bug #158638).
+	if use !python && use doc; then
+		epatch "${FILESDIR}"/${PN}-2.16.2-no_python_module_docs.patch
+	fi
+
+	# chown on fbsd doesn't have --reference.  Bug #183691
+	epatch "${FILESDIR}"/${PN}-2.18.1-fbsd.patch
+
+	# fixes failing python test due to libtool 2.2, bug #216110
+	epatch "${FILESDIR}/${PN}-2.22.1-fix-libtool-2.2.patch"
+
+	# disable pyc compiling
+	mv "${S}"/py-compile "${S}"/py-compile.orig
+	ln -s $(type -P true) "${S}"/py-compile
+
+	eautoreconf
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins
+}
diff --git a/app-editors/gedit/gedit-2.22.3.ebuild b/app-editors/gedit/gedit-2.22.3.ebuild
index 26853ef5f409..231c9672c40b 100644
--- a/app-editors/gedit/gedit-2.22.3.ebuild
+++ b/app-editors/gedit/gedit-2.22.3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.22.3.ebuild,v 1.6 2008/08/17 19:27:03 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.22.3.ebuild,v 1.7 2008/09/15 03:52:40 ford_prefect Exp $
 
 inherit gnome2 python eutils autotools
 
@@ -28,6 +28,7 @@ RDEPEND=">=gnome-base/gconf-2
 		>=dev-python/pygobject-2.12
 		>=dev-python/pygtk-2.12
 		>=dev-python/pygtksourceview-2.2
+		>=dev-python/gnome-python-2.22.0
 	)"
 
 DEPEND="${RDEPEND}