version bump

(Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 105 insertions, 1 deletions

diff --git a/app-admin/syslog-ng/ChangeLog b/app-admin/syslog-ng/ChangeLog
index 003a3d140492..3fb27fe1a356 100644
--- a/app-admin/syslog-ng/ChangeLog
+++ b/app-admin/syslog-ng/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/syslog-ng
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.370 2013/12/23 00:55:30 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.371 2013/12/31 08:24:58 mr_bones_ Exp $
+
+*syslog-ng-3.4.7 (31 Dec 2013)
+
+  31 Dec 2013; Michael Sterrett <mr_bones_@gentoo.org> +syslog-ng-3.4.7.ebuild:
+  version bump
 
   23 Dec 2013; Tom Wijsman <TomWij@gentoo.org> -files/syslog-ng.confd:
   [QA] Remove unused files.
diff --git a/app-admin/syslog-ng/syslog-ng-3.4.7.ebuild b/app-admin/syslog-ng/syslog-ng-3.4.7.ebuild
new file mode 100644
index 000000000000..9705b7a0ebc0
--- /dev/null
+++ b/app-admin/syslog-ng/syslog-ng-3.4.7.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.4.7.ebuild,v 1.1 2013/12/31 08:24:58 mr_bones_ Exp $
+
+EAPI=5
+inherit eutils multilib systemd
+
+MY_PV=${PV/_/}
+DESCRIPTION="syslog replacement with advanced filtering features"
+HOMEPAGE="http://www.balabit.com/network-security/syslog-ng"
+SRC_URI="http://www.balabit.com/downloads/files/syslog-ng/sources/${MY_PV}/source/syslog-ng_${MY_PV}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="caps dbi geoip ipv6 json mongodb +pcre smtp spoof-source ssl systemd tcpd"
+RESTRICT="test"
+
+RDEPEND="
+	pcre? ( dev-libs/libpcre )
+	spoof-source? ( net-libs/libnet:1.1 )
+	ssl? ( dev-libs/openssl:= )
+	smtp? ( net-libs/libesmtp )
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
+	>=dev-libs/eventlog-0.2.12
+	>=dev-libs/glib-2.10.1:2
+	json? ( >=dev-libs/json-c-0.9 )
+	caps? ( sys-libs/libcap )
+	geoip? ( >=dev-libs/geoip-1.5.0 )
+	dbi? ( >=dev-db/libdbi-0.8.3 )
+	systemd? ( sys-apps/systemd )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/flex"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_configure() {
+	econf \
+		--with-ivykis=internal \
+		--with-libmongo-client=internal \
+		--sysconfdir=/etc/syslog-ng \
+		--localstatedir=/var/lib/syslog-ng \
+		--with-pidfile-dir=/var/run \
+		--with-module-dir=/usr/$(get_libdir)/syslog-ng \
+		$(systemd_with_unitdir) \
+		$(use_enable systemd) \
+		$(use_enable caps linux-caps) \
+		$(use_enable geoip) \
+		$(use_enable ipv6) \
+		$(use_enable json) \
+		$(use_enable mongodb) \
+		$(use_enable pcre) \
+		$(use_enable smtp) \
+		$(use_enable spoof-source) \
+		$(use_enable dbi sql) \
+		$(use_enable ssl) \
+		$(use_enable tcpd tcp-wrapper)
+}
+
+src_install() {
+	# -j1 for bug #484470
+	emake -j1 DESTDIR="${D}" install
+
+	dodoc AUTHORS NEWS contrib/syslog-ng.conf* contrib/syslog2ng \
+		"${FILESDIR}/${PV%.*}/syslog-ng.conf.gentoo.hardened" \
+		"${FILESDIR}/syslog-ng.logrotate.hardened" \
+		"${FILESDIR}/README.hardened"
+
+	# Install default configuration
+	insinto /etc/syslog-ng
+	if use userland_BSD ; then
+		newins "${FILESDIR}/${PV%.*}/syslog-ng.conf.gentoo.fbsd" syslog-ng.conf
+	else
+		newins "${FILESDIR}/${PV%.*}/syslog-ng.conf.gentoo" syslog-ng.conf
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/syslog-ng.logrotate" syslog-ng
+
+	newinitd "${FILESDIR}/${PV%.*}/syslog-ng.rc6" syslog-ng
+	newconfd "${FILESDIR}/${PV%.*}/syslog-ng.confd" syslog-ng
+	keepdir /etc/syslog-ng/patterndb.d /var/lib/syslog-ng
+	prune_libtool_files --modules
+}
+
+pkg_postinst() {
+	elog "For detailed documentation please see the upstream website:"
+	elog "http://www.balabit.com/sites/default/files/documents/syslog-ng-ose-3.4-guides/en/syslog-ng-ose-v3.4-guide-admin/html/index.html"
+
+	# bug #355257
+	if ! has_version app-admin/logrotate ; then
+		echo
+		elog "It is highly recommended that app-admin/logrotate be emerged to"
+		elog "manage the log files.  ${PN} installs a file in /etc/logrotate.d"
+		elog "for logrotate to use."
+		echo
+	fi
+}