version bump, fix bug 522656

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xAABEFD55)

3 files changed, 79 insertions, 3 deletions

diff --git a/app-backup/snapper/ChangeLog b/app-backup/snapper/ChangeLog
index 4f6c2d3ba573..47c1342ed76f 100644
--- a/app-backup/snapper/ChangeLog
+++ b/app-backup/snapper/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-backup/snapper
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v 1.6 2014/09/15 06:38:13 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v 1.7 2014/11/15 14:38:53 dlan Exp $
+
+*snapper-0.2.4 (15 Nov 2014)
+
+  15 Nov 2014; Yixun Lan <dlan@gentoo.org> +snapper-0.2.4.ebuild,
+  snapper-9999.ebuild:
+  version bump, fix bug 522656
 
 *snapper-0.2.3-r1 (15 Sep 2014)
 
diff --git a/app-backup/snapper/snapper-0.2.4.ebuild b/app-backup/snapper/snapper-0.2.4.ebuild
new file mode 100644
index 000000000000..6c4f554d4bd2
--- /dev/null
+++ b/app-backup/snapper/snapper-0.2.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-0.2.4.ebuild,v 1.1 2014/11/15 14:38:53 dlan Exp $
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="Command-line program for btrfs and ext4 snapshot management"
+HOMEPAGE="http://snapper.io/"
+SRC_URI="ftp://ftp.suse.com/pub/projects/snapper/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+btrfs ext4 lvm pam xattr"
+
+RDEPEND="dev-libs/boost[threads]
+	dev-libs/libxml2
+	dev-libs/icu:=
+	sys-apps/acl
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/libintl
+	btrfs? ( >=sys-fs/btrfs-progs-3.17.1 )
+	ext4? ( sys-fs/e2fsprogs )
+	lvm? ( sys-fs/lvm2 )
+	pam? ( sys-libs/pam )
+	xattr? ( sys-apps/attr )"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS README )
+
+src_prepare() {
+	epatch "${FILESDIR}"/cron-confd.patch
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-conf="/etc/conf.d"
+		--docdir="/usr/share/doc/${PF}"
+		--disable-zypp
+		$(use_enable btrfs)
+		$(use_enable ext4)
+		$(use_enable lvm)
+		$(use_enable pam)
+		$(use_enable xattr xattrs)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# Existing configuration file required to function
+	newconfd data/sysconfig.snapper snapper
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	elog "In order to use Snapper, you need to set up"
+	elog "at least one config first. To do this, run:"
+	elog "snapper create-config <subvolume>"
+	elog "For more information, see man (8) snapper or"
+	elog "http://snapper.io/documentation.html"
+}
diff --git a/app-backup/snapper/snapper-9999.ebuild b/app-backup/snapper/snapper-9999.ebuild
index 97b813dfbe3d..85bfa22d1dab 100644
--- a/app-backup/snapper/snapper-9999.ebuild
+++ b/app-backup/snapper/snapper-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-9999.ebuild,v 1.4 2014/09/12 19:32:35 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-9999.ebuild,v 1.5 2014/11/15 14:38:53 dlan Exp $
 
 EAPI=5
 
@@ -26,7 +26,7 @@ RDEPEND="dev-libs/boost[threads]
 	sys-apps/util-linux
 	sys-libs/zlib
 	virtual/libintl
-	btrfs? ( sys-fs/btrfs-progs )
+	btrfs? ( >=sys-fs/btrfs-progs-3.17.1 )
 	ext4? ( sys-fs/e2fsprogs )
 	lvm? ( sys-fs/lvm2 )
 	pam? ( sys-libs/pam )