Bump to latest version, thanks to Attila Jecs and Jorma Rus in bug #137716.

(Portage version: 2.1.1_pre1-r5)

3 files changed, 139 insertions, 1 deletions

diff --git a/app-cdr/k3b/ChangeLog b/app-cdr/k3b/ChangeLog
index 9d5c7cc970c2..2e0bd915ac4f 100644
--- a/app-cdr/k3b/ChangeLog
+++ b/app-cdr/k3b/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.154 2006/06/24 09:42:11 genstef Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.155 2006/06/30 17:27:01 flameeyes Exp $
+
+*k3b-0.12.16 (30 Jun 2006)
+
+  30 Jun 2006; Diego Pettenò <flameeyes@gentoo.org> +k3b-0.12.16.ebuild:
+  Bump to latest version, thanks to Attila Jecs and Jorma Rus in bug #137716.
 
   24 Jun 2006; Stefan Schweizer <genstef@gentoo.org> k3b-0.12.14.ebuild,
   k3b-0.12.15.ebuild:
diff --git a/app-cdr/k3b/files/digest-k3b-0.12.16 b/app-cdr/k3b/files/digest-k3b-0.12.16
new file mode 100644
index 000000000000..5c56a7a54b8c
--- /dev/null
+++ b/app-cdr/k3b/files/digest-k3b-0.12.16
@@ -0,0 +1,6 @@
+MD5 cac9b8230295c1756581399b3bbd0687 k3b-0.12.16.tar.bz2 4004784
+RMD160 b4b64924096581bcb0c3432f99f0e27ffe0aca79 k3b-0.12.16.tar.bz2 4004784
+SHA256 bc686f6e596df32f2c305a1f4948ceddbbfb067045e6b9b314af615319d11fe6 k3b-0.12.16.tar.bz2 4004784
+MD5 1dc3edf8afff8b1c9064b42335a61add k3b-i18n-0.12.16.tar.bz2 5020555
+RMD160 de87783da39d82981fc7bed731cf8031afb70501 k3b-i18n-0.12.16.tar.bz2 5020555
+SHA256 6cb9466878f2386e3b30347b013405322f2306f48d037e527febf6aca56b1ff5 k3b-i18n-0.12.16.tar.bz2 5020555
diff --git a/app-cdr/k3b/k3b-0.12.16.ebuild b/app-cdr/k3b/k3b-0.12.16.ebuild
new file mode 100644
index 000000000000..b424c02cea63
--- /dev/null
+++ b/app-cdr/k3b/k3b-0.12.16.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-0.12.16.ebuild,v 1.1 2006/06/30 17:27:01 flameeyes Exp $
+
+inherit kde eutils
+
+DESCRIPTION="K3b, KDE CD Writing Software"
+HOMEPAGE="http://www.k3b.org/"
+SRC_URI="mirror://sourceforge/k3b/${P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="alsa css dvdr encode ffmpeg flac hal kde mp3 musepack musicbrainz sndfile vcd vorbis"
+
+DEPEND="kde? ( || ( kde-base/kdesu kde-base/kdebase ) )
+	hal? ( sys-apps/dbus sys-apps/hal )
+	media-libs/libsamplerate
+	media-libs/taglib
+	>=media-sound/cdparanoia-3.9.8
+	sndfile? ( media-libs/libsndfile )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac )
+	mp3? ( media-libs/libmad )
+	musepack? ( media-libs/libmpcdec )
+	vorbis? ( media-libs/libvorbis )
+	musicbrainz? ( media-libs/musicbrainz )
+	encode? ( media-sound/lame )
+	alsa? ( media-libs/alsa-lib )"
+
+RDEPEND="${DEPEND}
+	virtual/cdrtools
+	>=app-cdr/cdrdao-1.1.7-r3
+	media-sound/normalize
+	dvdr? ( app-cdr/dvd+rw-tools )
+	css? ( media-libs/libdvdcss )
+	encode? ( media-sound/sox
+			  media-video/transcode )
+	vcd? ( media-video/vcdimager )"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+need-kde 3.4
+
+I18N="${PN}-i18n-${PV}"
+
+# Supported languages and translated documentation
+LANGS="af bg bn br bs ca cs cy da de el en_GB es et eu fr ga he hi hu is it ja km lt mk ms nb nds nl nn pa pl pt pt_BR ro ru se sl sr sr@Latn sv ta tr uk zh_CN"
+
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
+	IUSE="${IUSE} linguas_${X}"
+done
+
+pkg_setup() {
+	if use hal && ! built_with_use sys-apps/dbus qt3; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"hal\" USE flag enabled,"
+		eerror "but sys-apps/dbus is not built with Qt3 support."
+		die "rebuild sys-apps/dbus with the qt3 useflag"
+	fi
+
+	kde_pkg_setup
+}
+
+src_unpack() {
+	kde_src_unpack
+
+	local MAKE_LANGS
+	for X in ${LANGS}; do
+		use linguas_${X} && MAKE_LANGS="${MAKE_LANGS} ${X}"
+	done
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		cd "${WORKDIR}/${I18N}"
+		sed -i -e "s,^SUBDIRS = .*,SUBDIRS = ${MAKE_LANGS}," Makefile.in
+	fi
+}
+
+src_compile() {
+	local myconf="--enable-libsuffix= \
+			--with-external-libsamplerate	\
+			--without-resmgr		\
+			$(use_with kde k3bsetup)	\
+			$(use_with hal)			\
+			$(use_with encode lame)		\
+			$(use_with ffmpeg)		\
+			$(use_with flac)		\
+			$(use_with vorbis oggvorbis)	\
+			$(use_with sndfile)		\
+			$(use_with mp3 libmad)		\
+			$(use_with musepack)		\
+			$(use_with musicbrainz)		\
+			$(use_with alsa)"
+
+	# Build process of K3b
+	kde_src_compile
+
+	# Build process of K3b-i18n
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_compile
+	fi
+}
+
+src_install() {
+	kde_src_install
+	dodoc FAQ KNOWNBUGS PERMISSIONS
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_install
+	fi
+
+	# Move menu entry
+	if use kde; then
+		mv ${D}/usr/share/applnk/Settings/System/k3bsetup2.desktop ${D}/usr/share/applications/kde/
+	fi
+	rm -fR ${D}/usr/share/applnk/
+}
+
+pkg_postinst() {
+	echo
+	einfo "Make sure you have proper read/write permissions on the cdrom device(s)."
+	einfo "Usually, it is sufficient to be in the cdrom group."
+	echo
+}