Version bump to 1.0.2.

(Portage version: 2.1.3_rc4)

3 files changed, 154 insertions, 1 deletions

diff --git a/app-cdr/k3b/ChangeLog b/app-cdr/k3b/ChangeLog
index df3e864c68aa..dd200f05f39b 100644
--- a/app-cdr/k3b/ChangeLog
+++ b/app-cdr/k3b/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.191 2007/05/26 14:29:32 philantrop Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.192 2007/06/24 19:31:41 philantrop Exp $
+
+*k3b-1.0.2 (24 Jun 2007)
+
+  24 Jun 2007; Wulf C. Krueger <philantrop@gentoo.org> +k3b-1.0.2.ebuild:
+  Version bump to 1.0.2.
 
 *k3b-1.0.1-r1 (26 May 2007)
 
diff --git a/app-cdr/k3b/files/digest-k3b-1.0.2 b/app-cdr/k3b/files/digest-k3b-1.0.2
new file mode 100644
index 000000000000..fc127f392a12
--- /dev/null
+++ b/app-cdr/k3b/files/digest-k3b-1.0.2
@@ -0,0 +1,6 @@
+MD5 b9307b3de0d15880a57c23a007bffca4 k3b-1.0.2.tar.bz2 5098893
+RMD160 5fbe00e94ee61c60125e19ec558e4f6dd8505967 k3b-1.0.2.tar.bz2 5098893
+SHA256 957bf427b9919a21e5b61aa20046cd7b51bb3867cea4cbe4a6c8bd28af36f9f0 k3b-1.0.2.tar.bz2 5098893
+MD5 3c9b3e76e7781f15b1373f2f5c1dc0b3 k3b-i18n-1.0.2.tar.bz2 7530193
+RMD160 0fcba8a8f34f9252d0b66027999f4c7bf55c9d0a k3b-i18n-1.0.2.tar.bz2 7530193
+SHA256 814094e3afb2bfa1664e48f9107a7177f01a7c19a5770b9f51de4fbf39afdac8 k3b-i18n-1.0.2.tar.bz2 7530193
diff --git a/app-cdr/k3b/k3b-1.0.2.ebuild b/app-cdr/k3b/k3b-1.0.2.ebuild
new file mode 100644
index 000000000000..b76e1464df88
--- /dev/null
+++ b/app-cdr/k3b/k3b-1.0.2.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.0.2.ebuild,v 1.1 2007/06/24 19:31:41 philantrop Exp $
+
+inherit kde eutils
+
+MY_P=${P/_/}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="K3b, KDE CD Writing Software"
+HOMEPAGE="http://www.k3b.org/"
+SRC_URI="mirror://sourceforge/k3b/${MY_P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa css dvdr dvdread encode ffmpeg flac hal kde mp3 musepack musicbrainz
+	sndfile vcd vorbis emovix"
+
+DEPEND="kde? ( || ( kde-base/kdesu kde-base/kdebase ) )
+	hal? ( || ( dev-libs/dbus-qt3-old
+				( <sys-apps/dbus-0.90 >=sys-apps/dbus-0.30 ) )
+		sys-apps/hal )
+	media-libs/libsamplerate
+	media-libs/taglib
+	>=media-sound/cdparanoia-3.9.8
+	sndfile? ( media-libs/libsndfile )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac )
+	mp3? ( media-libs/libmad )
+	musepack? ( media-libs/libmpcdec )
+	vorbis? ( media-libs/libvorbis )
+	musicbrainz? ( media-libs/musicbrainz )
+	encode? ( media-sound/lame )
+	alsa? ( media-libs/alsa-lib )
+	dvdread? ( media-libs/libdvdread )"
+
+RDEPEND="${DEPEND}
+	virtual/cdrtools
+	>=app-cdr/cdrdao-1.1.7-r3
+	media-sound/normalize
+	dvdr? ( >=app-cdr/dvd+rw-tools-7.0 )
+	css? ( media-libs/libdvdcss )
+	encode? ( media-sound/sox
+				media-video/transcode )
+	vcd? ( media-video/vcdimager )
+	emovix? ( media-video/emovix )"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+need-kde 3.5
+
+I18N="${PN}-i18n-${PV}"
+
+# Supported languages and translated documentation
+LANGS="af ar bg br bs ca cs cy da de el en_GB es et eu fa fi fr ga gl he hi hu is it ja ka lt mk ms nb nds nl nn pa pl pt pt_BR ru rw se sk sr sr@Latn sv ta tr uk uz zh_CN zh_TW"
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
+	IUSE="${IUSE} linguas_${X}"
+done
+
+pkg_setup() {
+	if use hal && has_version '<sys-apps/dbus-0.91' && ! built_with_use sys-apps/dbus qt3; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"hal\" USE flag enabled,"
+		eerror "but sys-apps/dbus is not built with Qt3 support."
+		die "Please, rebuild sys-apps/dbus with the \"qt3\" USE flag."
+	fi
+	if use encode && ! built_with_use media-video/transcode dvdread; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"encode\""
+		eerror "USE flag enabled, however media-video/transcode was not built"
+		eerror "with libdvdread support. Also keep in mind that enabling"
+		eerror "the dvdread USE flag will cause k3b to use libdvdread as well."
+		die "Please, rebuild media-video/transcode with the \"dvdread\" USE flag."
+	fi
+
+	use kde || elog "You haven't set the kde use flag. k3bsetup won't be installed."
+
+	kde_pkg_setup
+}
+
+src_unpack() {
+	kde_src_unpack
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		cd "${WORKDIR}/${I18N}"
+		for X in ${LANGS}; do
+			use linguas_${X} || rm -rf "${X}"
+		done
+		rm -f configure
+	fi
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	local myconf="--enable-libsuffix= 		\
+			--with-external-libsamplerate	\
+			--without-resmgr				\
+			--without-cdrecord-suid-root	\
+			$(use_with kde k3bsetup)		\
+			$(use_with hal)					\
+			$(use_with encode lame)			\
+			$(use_with ffmpeg)				\
+			$(use_with flac)				\
+			$(use_with vorbis oggvorbis)	\
+			$(use_with sndfile)				\
+			$(use_with mp3 libmad)			\
+			$(use_with musepack)			\
+			$(use_with musicbrainz)			\
+			$(use_with alsa)"
+
+	# Build process of K3b
+	kde_src_compile
+
+	# Build process of K3b-i18n
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_compile
+	fi
+}
+
+src_install() {
+	kde_src_install
+	dodoc FAQ KNOWNBUGS PERMISSIONS
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_install
+	fi
+}
+
+pkg_preinst() {
+	kde_pkg_preinst
+	use kde || rm ${D}/usr/share/applications/kde/k3bsetup2.desktop
+}
+
+pkg_postinst() {
+	echo
+	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
+	elog "Usually, it is sufficient to be in the cdrom group."
+	echo
+}