bump to 2.22.3. Translation updates.

(Portage version: 2.2_rc1/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

2 files changed, 120 insertions, 1 deletions

diff --git a/app-crypt/seahorse/ChangeLog b/app-crypt/seahorse/ChangeLog
index ae4beb02c58a..e484b79fa482 100644
--- a/app-crypt/seahorse/ChangeLog
+++ b/app-crypt/seahorse/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-crypt/seahorse
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.102 2008/06/15 12:34:40 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.103 2008/07/02 20:40:58 eva Exp $
+
+*seahorse-2.22.3 (02 Jul 2008)
+
+  02 Jul 2008; Gilles Dartiguelongue <eva@gentoo.org>
+  +seahorse-2.22.3.ebuild:
+  bump to 2.22.3. Translation updates.
 
   15 Jun 2008; Gilles Dartiguelongue <eva@gentoo.org>
   +files/seahorse-2.22.2-fbsd.patch, seahorse-2.22.2.ebuild:
diff --git a/app-crypt/seahorse/seahorse-2.22.3.ebuild b/app-crypt/seahorse/seahorse-2.22.3.ebuild
new file mode 100644
index 000000000000..c53f05d6d37b
--- /dev/null
+++ b/app-crypt/seahorse/seahorse-2.22.3.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/seahorse-2.22.3.ebuild,v 1.1 2008/07/02 20:40:58 eva Exp $
+
+EAPI="1"
+
+inherit eutils gnome2
+
+DESCRIPTION="A GNOME application for managing encryption keys"
+HOMEPAGE="http://www.gnome.org/projects/seahorse/index.html"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="applet avahi dbus debug epiphany gedit gnome-keyring ldap libnotify nautilus"
+
+RDEPEND=">=gnome-base/libgnome-2.14
+		 >=gnome-base/libgnomeui-2.10
+		 >=gnome-base/gnome-vfs-2.0
+		 >=gnome-base/libglade-2.0
+		 >=gnome-base/gconf-2.0
+		 >=dev-libs/glib-2.10
+		 >=x11-libs/gtk+-2.10
+		 net-libs/libsoup:2.4
+		 >=dev-libs/libxml2-2.6.0
+		 || (
+				=app-crypt/gnupg-1.4*
+				=app-crypt/gnupg-2.0*
+			)
+		 >=app-crypt/gpgme-1.0.0
+		   net-misc/openssh
+		   x11-misc/shared-mime-info
+		 avahi? ( >=net-dns/avahi-0.6 )
+		 dbus?	(
+			>=dev-libs/dbus-glib-0.72
+			applet? ( >=gnome-base/gnome-panel-2.10 )
+			epiphany? ( >=www-client/epiphany-2.14 )
+			gedit? ( >=app-editors/gedit-2.16 )
+		 )
+		 gnome-keyring? ( >=gnome-base/gnome-keyring-2.21.3.2 )
+		 ldap? ( net-nds/openldap )
+		 libnotify? ( >=x11-libs/libnotify-0.3.2 )
+		 nautilus? ( >=gnome-base/nautilus-2.12 )"
+DEPEND="${RDEPEND}
+		sys-devel/gettext
+		>=app-text/gnome-doc-utils-0.3.2
+		>=app-text/scrollkeeper-0.3
+		>=dev-util/pkgconfig-0.20
+		>=dev-util/intltool-0.35"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO THANKS"
+
+pkg_setup() {
+	if ! use dbus ; then
+		if use applet ; then
+			elog
+			elog "The panel applet requires that you build seahorse with DBUS support."
+			elog
+		fi
+
+		if use gedit ; then
+			elog
+			elog "The GEdit plugin requires that you build seahorse with DBUS support."
+			elog
+		fi
+
+		if use epiphany ; then
+			elog
+			elog "The epiphany plugin requires that you build seahorse with DBUS support."
+			elog
+		fi
+
+		eerror "Please add dbus to your USE flags and re-emerge seahorse"
+		eerror "plugins require dbus support"
+	fi
+
+	G2CONF="${G2CONF}
+		--enable-ssh
+		--disable-scrollkeeper
+		--disable-update-mime-database
+		--enable-hkp --with-keyserver --enable-agent
+		$(use_enable applet)
+		$(use_enable avahi sharing)
+		$(use_enable dbus)
+		$(use_enable debug)
+		$(use_enable epiphany)
+		$(use_enable gedit)
+		$(use_enable gnome-keyring)
+		$(use_enable ldap)
+		$(use_enable libnotify)
+		$(use_enable nautilus)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+	epatch "${FILESDIR}/${PN}-0.9.10-update-mime.patch"
+
+	# Fix building on fbsd
+	epatch "${FILESDIR}/${PN}-2.22.2-fbsd.patch"
+}
+
+src_install() {
+	gnome2_src_install
+
+	# remove conflicts with x11-misc/shared-mime-info
+	rm -rf "${D}/usr/share/mime/"{application,magic,globs,XMLnamespaces}
+
+	chmod -s "${D}/usr/bin/seahorse-agent"
+	chmod -s "${D}/usr/bin/seahorse-daemon"
+
+	exeinto /etc/X11/xinit/xinitrc.d/
+	doexe "${FILESDIR}/70-seahorse-agent"
+}