Version bump for Gnome 3.8

(Portage version: 2.1.11.58/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 73 insertions, 1 deletions

diff --git a/app-crypt/seahorse/ChangeLog b/app-crypt/seahorse/ChangeLog
index 2ff8e8114a37..f5d85e202717 100644
--- a/app-crypt/seahorse/ChangeLog
+++ b/app-crypt/seahorse/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-crypt/seahorse
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.164 2013/03/05 22:53:33 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.165 2013/03/28 16:29:29 pacho Exp $
+
+*seahorse-3.8.0 (28 Mar 2013)
+
+  28 Mar 2013; Pacho Ramos <pacho@gentoo.org> +seahorse-3.8.0.ebuild:
+  Version bump for Gnome 3.8
 
   05 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org> -seahorse-3.4.1.ebuild,
   -files/seahorse-3.4.1-g_clear_object.patch:
diff --git a/app-crypt/seahorse/seahorse-3.8.0.ebuild b/app-crypt/seahorse/seahorse-3.8.0.ebuild
new file mode 100644
index 000000000000..4a8c449b09b4
--- /dev/null
+++ b/app-crypt/seahorse/seahorse-3.8.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/seahorse-3.8.0.ebuild,v 1.1 2013/03/28 16:29:29 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+
+inherit gnome2
+
+DESCRIPTION="A GNOME application for managing encryption keys"
+HOMEPAGE="http://www.gnome.org/projects/seahorse/index.html"
+
+LICENSE="GPL-2+ FDL-1.1+"
+SLOT="0"
+IUSE="avahi debug ldap"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+COMMON_DEPEND="
+	>=app-crypt/gcr-3.3.4:=
+	>=dev-libs/glib-2.10:2
+	>=x11-libs/gtk+-3.4:3
+	>=app-crypt/libsecret-0.5
+	>=net-libs/libsoup-2.24.0:2.4
+	x11-misc/shared-mime-info
+
+	net-misc/openssh
+	>=app-crypt/gpgme-1
+	|| (
+		=app-crypt/gnupg-2.0*
+		=app-crypt/gnupg-1.4* )
+
+	avahi? ( >=net-dns/avahi-0.6:= )
+	ldap? ( net-nds/openldap:= )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# Need seahorse-plugins git snapshot
+RDEPEND="${COMMON_DEPEND}
+	!<app-crypt/seahorse-plugins-2.91.0_pre20110114
+"
+
+src_prepare() {
+	# FIXME: Do not mess with CFLAGS with USE="debug"
+	sed -e '/CFLAGS="$CFLAGS -g/d' \
+		-e '/CFLAGS="$CFLAGS -O0/d' \
+		-i configure.ac configure || die "sed 1 failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	G2CONF="${G2CONF}
+		--enable-pgp
+		--enable-ssh
+		--enable-pkcs11
+		--disable-static
+		--enable-hkp
+		$(use_enable avahi sharing)
+		$(use_enable debug)
+		$(use_enable ldap)
+		ITSTOOL=$(type -P true)"
+
+	gnome2_src_configure
+}