Version bump. Clean up old revision.

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key C6085806)

3 files changed, 79 insertions, 36 deletions

diff --git a/app-dicts/verbiste/ChangeLog b/app-dicts/verbiste/ChangeLog
index 9e57575cdc16..24da67c06b2f 100644
--- a/app-dicts/verbiste/ChangeLog
+++ b/app-dicts/verbiste/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-dicts/verbiste
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-dicts/verbiste/ChangeLog,v 1.38 2013/05/20 08:33:18 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-dicts/verbiste/ChangeLog,v 1.39 2013/09/01 10:57:39 eva Exp $
+
+*verbiste-0.1.38 (01 Sep 2013)
+
+  01 Sep 2013; Gilles Dartiguelongue <eva@gentoo.org> -verbiste-0.1.23.ebuild,
+  +verbiste-0.1.38.ebuild:
+  Version bump. Clean up old revision.
 
   20 May 2013; Agostino Sarubbo <ago@gentoo.org> verbiste-0.1.35.ebuild:
   Stable for x86, wrt bug #461056
diff --git a/app-dicts/verbiste/verbiste-0.1.23.ebuild b/app-dicts/verbiste/verbiste-0.1.23.ebuild
deleted file mode 100644
index b377efebf234..000000000000
--- a/app-dicts/verbiste/verbiste-0.1.23.ebuild
+++ /dev/null
@@ -1,35 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-dicts/verbiste/verbiste-0.1.23.ebuild,v 1.6 2012/05/03 02:18:34 jdhore Exp $
-
-EAPI="2"
-
-DESCRIPTION="French conjugation system"
-HOMEPAGE="http://sarrazip.com/dev/verbiste.html"
-SRC_URI="http://sarrazip.com/dev/${P}.tar.gz"
-
-SLOT="0"
-LICENSE="GPL-2"
-KEYWORDS="amd64 ppc x86"
-
-IUSE="gnome gtk"
-
-RDEPEND=">=dev-libs/libxml2-2.4.0:2
-	gtk? ( >=x11-libs/gtk+-2.6:2 )
-	gnome? ( || ( gnome-base/gnome-panel[bonobo] <gnome-base/gnome-panel-2.32 )
-		>=gnome-base/libgnomeui-2.0 )"
-
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-src_configure() {
-	econf \
-		$(use_with gtk gtk-app) \
-		$(use_with gnome gnome-app) \
-		$(use_with gnome gnome-applet) || die "econf failed"
-}
-
-src_install() {
-	emake install DESTDIR="${D}" || die "can't install"
-	dodoc AUTHORS ChangeLog HACKING LISEZMOI NEWS README THANKS TODO
-}
diff --git a/app-dicts/verbiste/verbiste-0.1.38.ebuild b/app-dicts/verbiste/verbiste-0.1.38.ebuild
new file mode 100644
index 000000000000..51d8169aa0b1
--- /dev/null
+++ b/app-dicts/verbiste/verbiste-0.1.38.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-dicts/verbiste/verbiste-0.1.38.ebuild,v 1.1 2013/09/01 10:57:39 eva Exp $
+
+EAPI="5"
+
+inherit eutils gnome2-utils fdo-mime
+
+DESCRIPTION="French conjugation system"
+HOMEPAGE="http://sarrazip.com/dev/verbiste.html"
+SRC_URI="http://sarrazip.com/dev/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE="gnome gtk"
+
+RDEPEND="
+	>=dev-libs/libxml2-2.4.0:2
+	gtk? ( >=x11-libs/gtk+-2.6:2 )
+	gnome? (
+		gnome-base/gnome-panel[bonobo]
+		>=gnome-base/libgnomeui-2.0 )
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	econf \
+		--with-console-app \
+		$(use_with gtk gtk-app) \
+		$(use_with gnome gnome-app) \
+		$(use_with gnome gnome-applet)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+	dodoc HACKING LISEZMOI
+	# file is only installed with USE=gnome
+	if use gtk && ! use gnome ; then
+		sed -e 's/Exec=.*/Exec=verbiste-gtk/' \
+			-i src/gnome/verbiste.desktop || die
+		insinto usr/share/applications
+		doins src/gnome/verbiste.desktop
+	fi
+}
+
+pkg_preinst() {
+	if use gtk || use gnome ; then
+		gnome2_icon_savelist
+	fi
+}
+
+pkg_postinst() {
+	if use gtk || use gnome ; then
+		fdo-mime_desktop_database_update
+		fdo-mime_mime_database_update
+		gnome2_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use gtk || use gnome ; then
+		fdo-mime_desktop_database_update
+		fdo-mime_mime_database_update
+		gnome2_icon_cache_update
+	fi
+}