Build from source, unless USE=binary is specified. Install EAPI cheat sheet. Add missing dependency on recode. Remove old.

(Portage version: 2.1.13.7/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

5 files changed, 94 insertions, 44 deletions

diff --git a/app-doc/pms/ChangeLog b/app-doc/pms/ChangeLog
index 47b2f8a8d70f..eb234f71204f 100644
--- a/app-doc/pms/ChangeLog
+++ b/app-doc/pms/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-doc/pms
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-doc/pms/ChangeLog,v 1.36 2013/02/07 21:34:12 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-doc/pms/ChangeLog,v 1.37 2013/08/09 21:07:47 ulm Exp $
+
+*pms-5-r1 (09 Aug 2013)
+
+  09 Aug 2013; Ulrich Müller <ulm@gentoo.org> -pms-4_p20110118.ebuild,
+  +pms-5-r1.ebuild, pms-9999.ebuild, metadata.xml:
+  Build from source, unless USE=binary is specified. Install EAPI cheat sheet.
+  Add missing dependency on recode. Remove old.
 
   07 Feb 2013; Ulrich Müller <ulm@gentoo.org> pms-4_p20110118.ebuild,
   pms-5.ebuild, pms-9999.ebuild:
diff --git a/app-doc/pms/metadata.xml b/app-doc/pms/metadata.xml
index 0bd61deb8537..4c9cc22eae8c 100644
--- a/app-doc/pms/metadata.xml
+++ b/app-doc/pms/metadata.xml
@@ -1,15 +1,17 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<maintainer>
-		<email>ulm@gentoo.org</email>
-		<name>Ulrich Müller</name>
-	</maintainer>
-	<maintainer>
-		<email>fauli@gentoo.org</email>
-		<name>Christian Faulhammer</name>
-	</maintainer>
-	<use>
-		<flag name="html">Generate PMS as .html as well</flag>
-	</use>
+<maintainer>
+  <email>ulm@gentoo.org</email>
+  <name>Ulrich Müller</name>
+</maintainer>
+<maintainer>
+  <email>fauli@gentoo.org</email>
+  <name>Christian Faulhammer</name>
+</maintainer>
+<use>
+  <flag name="binary">Install pre-made PDF file instead of building
+    from sources</flag>
+  <flag name="html">Generate PMS as .html as well</flag>
+</use>
 </pkgmetadata>
diff --git a/app-doc/pms/pms-4_p20110118.ebuild b/app-doc/pms/pms-4_p20110118.ebuild
deleted file mode 100644
index b810af65518e..000000000000
--- a/app-doc/pms/pms-4_p20110118.ebuild
+++ /dev/null
@@ -1,22 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-doc/pms/pms-4_p20110118.ebuild,v 1.5 2013/02/07 21:34:12 ulm Exp $
-
-EAPI=2
-
-DESCRIPTION="Gentoo Package Manager Specification"
-HOMEPAGE="http://www.gentoo.org/proj/en/qa/pms.xml"
-SRC_URI="mirror://gentoo/${P}.pdf"
-
-LICENSE="CC-BY-SA-3.0"
-SLOT="0"
-KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~x86-netbsd ~ppc-openbsd ~x64-openbsd ~x86-openbsd ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
-IUSE=""
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	newdoc "${DISTDIR}"/${P}.pdf pms.pdf || die
-}
diff --git a/app-doc/pms/pms-5-r1.ebuild b/app-doc/pms/pms-5-r1.ebuild
new file mode 100644
index 000000000000..542e2320a870
--- /dev/null
+++ b/app-doc/pms/pms-5-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-doc/pms/pms-5-r1.ebuild,v 1.1 2013/08/09 21:07:47 ulm Exp $
+
+EAPI=5
+
+DESCRIPTION="Gentoo Package Manager Specification"
+HOMEPAGE="http://www.gentoo.org/proj/en/qa/pms.xml"
+SRC_URI="!binary? ( mirror://gentoo/${P}.tar.xz )
+	binary? ( mirror://gentoo/${P}.pdf )"
+
+LICENSE="CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~x86-netbsd ~ppc-openbsd ~x64-openbsd ~x86-openbsd ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="binary html"
+
+DEPEND="!binary? (
+		dev-tex/leaflet
+		dev-texlive/texlive-bibtexextra
+		dev-texlive/texlive-latex
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-latexrecommended
+		dev-texlive/texlive-science
+		html? (
+			app-text/recode
+			>=dev-tex/tex4ht-20090115_p0029
+		)
+	)"
+RDEPEND=""
+
+src_unpack() {
+	if use !binary; then
+		unpack ${A}
+	else
+		S="${WORKDIR}"
+		cp "${DISTDIR}"/${P}.pdf pms.pdf || die
+	fi
+}
+
+src_compile() {
+	if use !binary; then
+		emake
+		use html && emake html
+	fi
+}
+
+src_install() {
+	dodoc pms.pdf
+	if use !binary; then
+		dodoc eapi-cheatsheet.pdf
+		if use html; then
+			dohtml *.html pms.css $(shopt -s nullglob; echo *.png)
+			dosym {..,/usr/share/doc/${PF}/html}/eapi-cheatsheet.pdf
+		fi
+	else
+		use html && ewarn "USE=\"html\" has no effect with USE=\"binary\"."
+	fi
+}
diff --git a/app-doc/pms/pms-9999.ebuild b/app-doc/pms/pms-9999.ebuild
index e7926887b362..86e39500de1f 100644
--- a/app-doc/pms/pms-9999.ebuild
+++ b/app-doc/pms/pms-9999.ebuild
@@ -1,8 +1,9 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-doc/pms/pms-9999.ebuild,v 1.3 2013/02/07 21:34:12 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-doc/pms/pms-9999.ebuild,v 1.4 2013/08/09 21:07:47 ulm Exp $
+
+EAPI=5
 
-EAPI=4
 inherit git-2
 
 EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/${PN}.git
@@ -10,20 +11,21 @@ EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/${PN}.git
 
 DESCRIPTION="Gentoo Package Manager Specification (draft)"
 HOMEPAGE="http://www.gentoo.org/proj/en/qa/pms.xml"
-SRC_URI=""
 
 LICENSE="CC-BY-SA-3.0"
 SLOT="live"
-KEYWORDS=""
 IUSE="html"
 
-DEPEND="html? ( >=dev-tex/tex4ht-20090115_p0029 )
-	dev-tex/leaflet
+DEPEND="dev-tex/leaflet
 	dev-texlive/texlive-bibtexextra
 	dev-texlive/texlive-latex
-	dev-texlive/texlive-latexrecommended
 	dev-texlive/texlive-latexextra
-	dev-texlive/texlive-science"
+	dev-texlive/texlive-latexrecommended
+	dev-texlive/texlive-science
+	html? (
+		app-text/recode
+		>=dev-tex/tex4ht-20090115_p0029
+	)"
 RDEPEND=""
 
 src_compile() {
@@ -32,6 +34,9 @@ src_compile() {
 }
 
 src_install() {
-	dodoc pms.pdf
-	use html && dohtml *.html pms.css $(shopt -s nullglob; echo *.png)
+	dodoc pms.pdf eapi-cheatsheet.pdf
+	if use html; then
+		dohtml *.html pms.css $(shopt -s nullglob; echo *.png)
+		dosym {..,/usr/share/doc/${PF}/html}/eapi-cheatsheet.pdf
+	fi
 }