Version bump to 4.1.0; dropped Python 2.7 support as it fails on it for now and that will need to be adapted to work again, can't support 3.3 yet due to PyEnchant dependency. Fixes bug #488104, reported by Helmut Jarausch.

(Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

3 files changed, 66 insertions, 5 deletions

diff --git a/app-editors/retext/ChangeLog b/app-editors/retext/ChangeLog
index 9fe21c6a2cbc..2b5d06c9609a 100644
--- a/app-editors/retext/ChangeLog
+++ b/app-editors/retext/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for app-editors/retext
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/retext/ChangeLog,v 1.6 2013/10/13 07:54:18 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/retext/ChangeLog,v 1.7 2013/10/26 23:48:57 tomwij Exp $
+
+*retext-4.1.0 (26 Oct 2013)
+
+  26 Oct 2013; Tom Wijsman <TomWij@gentoo.org> +retext-4.1.0.ebuild,
+  retext-9999.ebuild:
+  Version bump to 4.1.0; dropped Python 2.7 support as it fails on it for now
+  and that will need to be adapted to work again, can't support 3.3 yet due to
+  PyEnchant dependency. Fixes bug #488104, reported by Helmut Jarausch.
 
   13 Oct 2013; Pacho Ramos <pacho@gentoo.org> retext-4.0.1-r2.ebuild:
   Also compatible with python3_3
diff --git a/app-editors/retext/retext-4.1.0.ebuild b/app-editors/retext/retext-4.1.0.ebuild
new file mode 100644
index 000000000000..c34758de5032
--- /dev/null
+++ b/app-editors/retext/retext-4.1.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/retext/retext-4.1.0.ebuild,v 1.1 2013/10/26 23:48:57 tomwij Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python3_2 )
+PLOCALES="ca cs cy da de es et eu fr it ja pl pt pt_BR ru sk uk zh_CN zh_TW"
+
+inherit distutils-r1 l10n
+
+MY_PN="ReText"
+MY_P="${MY_PN}-${PV/_/~}"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-2
+	EGIT_REPO_URI="git://git.code.sf.net/p/retext/git"
+	KEYWORDS=""
+else
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A Qt-based text editor for Markdown and reStructuredText"
+HOMEPAGE="http://sourceforge.net/p/retext/home/ReText/"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+spell"
+
+RDEPEND+="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/markups[${PYTHON_USEDEP}]
+	dev-python/PyQt4[webkit,${PYTHON_USEDEP}]
+	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}"/${MY_P}
+
+src_install() {
+	distutils-r1_src_install
+
+	newicon {icons/,}${PN}.png
+	newicon {icons/,}${PN}.svg
+
+	l10n_for_each_disabled_locale_do remove_locale
+
+	make_desktop_entry ${PN} "${MY_PN} Editor" ${PN} "Development;Utility;TextEditor"
+}
+
+remove_locale() {
+	find "${D}" -name "retext_${1}.qm" -delete || die "Failed to remove locale ${1}."
+}
diff --git a/app-editors/retext/retext-9999.ebuild b/app-editors/retext/retext-9999.ebuild
index 97074fa45ac0..680fcad50fc2 100644
--- a/app-editors/retext/retext-9999.ebuild
+++ b/app-editors/retext/retext-9999.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/retext/retext-9999.ebuild,v 1.2 2013/06/29 15:43:37 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/retext/retext-9999.ebuild,v 1.3 2013/10/26 23:48:57 tomwij Exp $
 
 EAPI="5"
 
-PYTHON_COMPAT=( python2_7 python3_2 )
+PYTHON_COMPAT=( python3_2 )
 PLOCALES="ca cs cy da de es et eu fr it ja pl pt pt_BR ru sk uk zh_CN zh_TW"
 
 inherit distutils-r1 l10n
@@ -48,8 +48,6 @@ src_install() {
 	l10n_for_each_disabled_locale_do remove_locale
 
 	make_desktop_entry ${PN} "${MY_PN} Editor" ${PN} "Development;Utility;TextEditor"
-
-	dosym /usr/bin/${PN}{.py,}
 }
 
 remove_locale() {