Version bump.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 90 insertions, 1 deletions

diff --git a/app-editors/nano/ChangeLog b/app-editors/nano/ChangeLog
index f9b1194e2db0..1632dfa381bc 100644
--- a/app-editors/nano/ChangeLog
+++ b/app-editors/nano/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.228 2009/02/17 05:17:22 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.229 2009/08/13 03:01:09 vapier Exp $
+
+*nano-2.1.10 (13 Aug 2009)
+
+  13 Aug 2009; Mike Frysinger <vapier@gentoo.org> +nano-2.1.10.ebuild:
+  Version bump.
 
 *nano-2.1.9 (17 Feb 2009)
 
diff --git a/app-editors/nano/nano-2.1.10.ebuild b/app-editors/nano/nano-2.1.10.ebuild
new file mode 100644
index 000000000000..4d6f4e97cccc
--- /dev/null
+++ b/app-editors/nano/nano-2.1.10.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.1.10.ebuild,v 1.1 2009/08/13 03:01:09 vapier Exp $
+
+EAPI=2
+inherit eutils
+if [[ ${PV} == "9999" ]] ; then
+	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
+	inherit subversion
+else
+	MY_P=${PN}-${PV/_}
+	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
+fi
+
+DESCRIPTION="GNU GPL'd Pico clone with more functionality"
+HOMEPAGE="http://www.nano-editor.org/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="debug justify minimal ncurses nls slang spell unicode"
+
+DEPEND=">=sys-libs/ncurses-5.2[unicode?]
+	nls? ( sys-devel/gettext )
+	!ncurses? ( slang? ( sys-libs/slang ) )"
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		subversion_src_unpack
+	else
+		unpack ${A}
+	fi
+	cd "${S}"
+	if [[ ! -e configure ]] ; then
+		./autogen.sh || die "autogen failed"
+	fi
+}
+
+src_configure() {
+	local myconf=""
+	use ncurses \
+		&& myconf="--without-slang" \
+		|| myconf="${myconf} $(use_with slang)"
+
+	econf \
+		--bindir=/bin \
+		$(use_enable !minimal color) \
+		$(use_enable !minimal multibuffer) \
+		$(use_enable !minimal nanorc) \
+		--disable-wrapping-as-root \
+		$(use_enable spell speller) \
+		$(use_enable justify) \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		$(use_enable unicode utf8) \
+		$(use_enable minimal tiny) \
+		${myconf} \
+		|| die "configure failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
+	dohtml *.html
+	insinto /etc
+	newins doc/nanorc.sample nanorc
+
+	dodir /usr/bin
+	dosym /bin/nano /usr/bin/nano
+
+	insinto /usr/share/nano
+	local f
+	for f in "${FILESDIR}"/*.nanorc ; do
+		[[ -e ${D}/usr/share/nano/${f##*/} ]] && continue
+		doins "${f}" || die
+		echo "# include \"/usr/share/nano/${f##*/}\"" >> "${D}"/etc/nanorc
+	done
+}
+
+pkg_postinst() {
+	einfo "More helpful info about nano, visit the GDP page:"
+	einfo "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
+}