Version bumped.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 114 insertions, 1 deletions

diff --git a/app-i18n/ibus-mozc/ChangeLog b/app-i18n/ibus-mozc/ChangeLog
index 2caef0fa5129..52278f0feff5 100644
--- a/app-i18n/ibus-mozc/ChangeLog
+++ b/app-i18n/ibus-mozc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/ibus-mozc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-mozc/ChangeLog,v 1.5 2010/07/29 17:29:33 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-mozc/ChangeLog,v 1.6 2010/08/19 18:02:44 matsuu Exp $
+
+*ibus-mozc-0.12.434.102 (19 Aug 2010)
+
+  19 Aug 2010; MATSUU Takuto <matsuu@gentoo.org>
+  +ibus-mozc-0.12.434.102.ebuild:
+  Version bumped.
 
 *ibus-mozc-0.12.422.102 (29 Jul 2010)
 
diff --git a/app-i18n/ibus-mozc/ibus-mozc-0.12.434.102.ebuild b/app-i18n/ibus-mozc/ibus-mozc-0.12.434.102.ebuild
new file mode 100644
index 000000000000..168382ba6c2e
--- /dev/null
+++ b/app-i18n/ibus-mozc/ibus-mozc-0.12.434.102.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-mozc/ibus-mozc-0.12.434.102.ebuild,v 1.1 2010/08/19 18:02:44 matsuu Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+inherit eutils multilib python toolchain-funcs
+
+MY_P="${P/ibus-}"
+DESCRIPTION="The Mozc engine for IBus Framework"
+HOMEPAGE="http://code.google.com/p/mozc/"
+SRC_URI="http://mozc.googlecode.com/files/${MY_P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ibus scim qt4"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/protobuf
+	net-misc/curl
+	sys-libs/zlib
+	ibus? ( >=app-i18n/ibus-1.2 )
+	scim? ( app-i18n/scim )
+	qt4? ( x11-libs/qt-gui:4 )"
+DEPEND="${RDEPEND}
+	dev-util/gtest
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+BUILDTYPE="${BUILDTYPE:-Release}"
+
+RESTRICT="test"
+
+pkg_setup() {
+	python_set_active_version 2
+}
+
+src_prepare() {
+	sed -i -e "s:/usr/lib/mozc:${EPREFIX}/usr/$(get_libdir)/mozc:" base/util.cc || die
+	epatch "${FILESDIR}/${PN}-0.11.365.102-gentoo.patch"
+}
+
+src_configure() {
+	"$(PYTHON)" build_mozc.py gyp || die "gyp failed"
+}
+
+src_compile() {
+	tc-export CC CXX AR AS RANLIB LD
+	export QTDIR="${EPREFIX}/usr"
+
+	local mytarget="server/server.gyp:mozc_server"
+	use ibus && mytarget="${mytarget} unix/ibus/ibus.gyp:ibus_mozc"
+	use scim && mytarget="${mytarget} unix/scim/scim.gyp:scim_mozc unix/scim/scim.gyp:scim_mozc_setup"
+	use qt4 && mytarget="${mytarget} gui/gui.gyp:mozc_tool"
+
+	"$(PYTHON)" build_mozc.py build_tools -c "${BUILDTYPE}" || die
+	"$(PYTHON)" build_mozc.py build -c "${BUILDTYPE}" ${mytarget} || die
+}
+
+src_test() {
+	"$(PYTHON)" build_mozc.py runtests -c "${BUILDTYPE}" || die
+}
+
+src_install() {
+	if use ibus ; then
+		exeinto /usr/libexec || die
+		newexe "out_linux/${BUILDTYPE}/ibus_mozc" ibus-engine-mozc || die
+		insinto /usr/share/ibus/component || die
+		doins "out_linux/${BUILDTYPE}/obj/gen/unix/ibus/mozc.xml" || die
+		insinto /usr/share/ibus-mozc || die
+		(
+			cd data/images/unix
+			newins ime_product_icon_opensource-32.png product_icon.png || die
+			for f in ui-*
+			do
+				newins ${f} ${f/ui-} || die
+			done
+		)
+
+	fi
+
+	if use scim ; then
+		exeinto "$(pkg-config --variable=moduledir scim)/IMEngine/" || die
+		newexe "out_linux/${BUILDTYPE}/lib.target/libscim_mozc.so" mozc.so || die
+		exeinto "$(pkg-config --variable=moduledir scim)/SetupUI/" || die
+		newexe "out_linux/${BUILDTYPE}/lib.target/libscim_mozc_setup.so" mozc-setup.so || die
+		insinto "$(pkg-config --variable=icondir scim)" || die
+		(
+			cd data/images/unix
+			newins ime_product_icon_opensource-32.png scim-mozc.png || die
+			for f in ui-*
+			do
+				newins ${f} ${f/ui-/scim-mozc-} || die
+			done
+		)
+	fi
+
+	exeinto "/usr/$(get_libdir)/mozc" || die
+	doexe "out_linux/${BUILDTYPE}/mozc_server" || die
+
+	if use qt4 ; then
+		exeinto "/usr/$(get_libdir)/mozc" || die
+		doexe "out_linux/${BUILDTYPE}/mozc_tool" || die
+	fi
+}