version bump with pcsc patch from bug 319243

(Portage version: 2.1.8.3/cvs/Linux i686)

3 files changed, 149 insertions, 1 deletions

diff --git a/app-mobilephone/gnokii/ChangeLog b/app-mobilephone/gnokii/ChangeLog
index 567b7e57adc3..7a44761b661d 100644
--- a/app-mobilephone/gnokii/ChangeLog
+++ b/app-mobilephone/gnokii/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-mobilephone/gnokii
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/gnokii/ChangeLog,v 1.104 2010/06/17 20:07:42 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/gnokii/ChangeLog,v 1.105 2010/08/10 13:13:34 fauli Exp $
+
+*gnokii-0.6.29 (10 Aug 2010)
+
+  10 Aug 2010; Christian Faulhammer <fauli@gentoo.org>
+  +gnokii-0.6.29.ebuild, +files/gnokii-0.6.29-pcsc.patch:
+  version bump with pcsc patch from bug 319243
 
   17 Jun 2010; Patrick Lauer <patrick@gentoo.org> gnokii-0.6.27-r2.ebuild,
   gnokii-0.6.27-r4.ebuild, gnokii-0.6.28.1.ebuild, gnokii-9999.ebuild:
diff --git a/app-mobilephone/gnokii/files/gnokii-0.6.29-pcsc.patch b/app-mobilephone/gnokii/files/gnokii-0.6.29-pcsc.patch
new file mode 100644
index 000000000000..539c208f5a9c
--- /dev/null
+++ b/app-mobilephone/gnokii/files/gnokii-0.6.29-pcsc.patch
@@ -0,0 +1,14 @@
+diff -rupN gnokii-0.6.29.orig/common/phones/pcsc.c gnokii-0.6.29new/common/phones/pcsc.c
+--- gnokii-0.6.29.orig/common/phones/pcsc.c	2010-07-29 08:38:28.000000000 +1000
++++ gnokii-0.6.29/common/phones/pcsc.c	2010-07-29 08:51:29.000000000 +1000
+@@ -199,8 +199,8 @@ static gn_error get_gn_error(PCSC_IOSTRU
+ 	case SCARD_W_UNPOWERED_CARD:
+ 	case SCARD_W_RESET_CARD:
+ 	case SCARD_W_REMOVED_CARD:
+-	case SCARD_W_INSERTED_CARD:
+-	 	return GN_ERR_SIMPROBLEM;
++	/* removed in pscc case SCARD_W_INSERTED_CARD:
++	 	return GN_ERR_SIMPROBLEM; */
+ 	case SCARD_E_NO_MEMORY:
+ 		return GN_ERR_MEMORYFULL;
+ 	case SCARD_F_WAITED_TOO_LONG:
diff --git a/app-mobilephone/gnokii/gnokii-0.6.29.ebuild b/app-mobilephone/gnokii/gnokii-0.6.29.ebuild
new file mode 100644
index 000000000000..83a61c2bf0d7
--- /dev/null
+++ b/app-mobilephone/gnokii/gnokii-0.6.29.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/gnokii/gnokii-0.6.29.ebuild,v 1.1 2010/08/10 13:13:34 fauli Exp $
+
+EAPI=2
+
+inherit eutils linux-info autotools
+
+DESCRIPTION="user space driver and tools for use with mobile phones"
+HOMEPAGE="http://www.gnokii.org/"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://www.gnokii.org/download/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+else
+	SRC_URI=""
+	KEYWORDS=""
+	EGIT_REPO_URI="git://git.savannah.nongnu.org/gnokii.git"
+	inherit git
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="nls bluetooth ical irda sms postgres mysql usb X debug"
+
+RDEPEND="!app-mobilephone/smstools
+	sys-apps/pcsc-lite
+	X? ( >=x11-libs/gtk+-2 )
+	bluetooth? ( net-wireless/bluez )
+	sms? (
+		!app-mobilephone/smstools
+		>=dev-libs/glib-2
+		postgres? ( >=dev-db/postgresql-base-8.0 )
+		mysql? ( >=virtual/mysql-4.1 )
+	)
+	ical? ( dev-libs/libical )
+	usb? ( =virtual/libusb-0* )"
+DEPEND="${RDEPEND}
+	irda? ( virtual/os-headers )
+	nls? ( sys-devel/gettext )
+	dev-util/intltool"
+
+CONFIG_CHECK="~UNIX98_PTYS"
+
+S="${WORKDIR}/${PN}-${PV%.1}"
+
+# Supported languages and translated documentation
+# Be sure all languages are prefixed with a single space!
+MY_AVAILABLE_LINGUAS=" cs de et fi fr it nl pl pt sk sl sv zh_CN"
+IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"
+
+src_prepare() {
+	if [ "$PV" != "9999" ]; then
+		epatch "${FILESDIR}"/${PN}-0.6.29-pcsc.patch
+	else
+		epatch "${FILESDIR}"/${P}-icon.patch
+		epatch "${FILESDIR}"/${P}-translations.patch
+		intltoolize --force --copy --automake || die "intltoolize error"
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	strip-linguas ${MY_AVAILABLE_LINGUAS}
+
+	local config_xdebug="--disable-xdebug"
+	use X && use debug && config_xdebug="--enable-xdebug"
+
+	econf \
+		$(use_enable nls) \
+		$(use_enable ical libical) \
+		$(use_enable usb libusb) \
+		$(use_enable irda) \
+		$(use_enable bluetooth) \
+		$(use_with X x) \
+		$(use_enable sms smsd) \
+		$(use_enable mysql) \
+		$(use_enable postgres) \
+		$(use_enable debug fulldebug) \
+		${config_xdebug} \
+		$(use_enable debug rlpdebug) \
+		--enable-security \
+		--disable-unix98test \
+		--enable-libpcsclite \
+		|| die "configure failed"
+}
+
+src_install() {
+	einstall || die "make install failed"
+
+	insinto /etc
+	doins Docs/sample/gnokiirc
+	sed -i -e 's:/usr/local:/usr:' "${D}/etc/gnokiirc"
+
+	# only one file needs suid root to make a pseudo device
+	fperms 4755 /usr/sbin/mgnokiidev
+
+	if use X; then
+		insinto /usr/share/pixmaps
+		newins Docs/sample/logo/gnokii.xpm xgnokii.xpm
+	fi
+
+	if use sms; then
+		pushd "${S}/smsd"
+		insinto /usr/share/doc/${PN}/smsd
+		use mysql && doins sms.tables.mysql.sql README.MySQL
+		use postgres && doins sms.tables.pq.sql
+		doins README ChangeLog README.Tru64 action
+		popd
+	fi
+}
+
+src_test() {
+	echo common/phones/fake.c >> ${S}/po/POTFILES.in
+	default
+}
+
+pkg_postinst() {
+	elog "Make sure the user that runs gnokii has read/write access to the device"
+	elog "which your phone is connected to."
+	elog "The simple way of doing that is to add your user to the uucp group."
+	if [ "$PV" == "9999" ]; then
+		elog "This is the GIT version of ${PN}. It is experimental but may have important bug fixes."
+		elog "You can keep track of the most recent commits at:"
+		elog "    http://git.savannah.gnu.org/cgit/gnokii.git/"
+		elog "Whenever there is a change you are interested in, you can re-emerge ${P}."
+	fi
+}