Version bump. Set proper depend on x11-libs/qt-gui[dbus] (bug #420907).

(Portage version: 2.2.0_alpha121/cvs/Linux x86_64)

3 files changed, 92 insertions, 3 deletions

diff --git a/app-text/djview/ChangeLog b/app-text/djview/ChangeLog
index 53c8bb02c68c..9306e5a4fe06 100644
--- a/app-text/djview/ChangeLog
+++ b/app-text/djview/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/djview
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/djview/ChangeLog,v 1.14 2012/06/07 18:47:39 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/djview/ChangeLog,v 1.15 2012/08/20 23:43:23 jer Exp $
+
+*djview-4.9 (20 Aug 2012)
+
+  20 Aug 2012; Jeroen Roovers <jer@gentoo.org> djview-4.8.ebuild,
+  +djview-4.9.ebuild:
+  Version bump. Set proper depend on x11-libs/qt-gui[dbus] (bug #420907).
 
   07 Jun 2012; Brent Baude <ranger@gentoo.org> djview-4.8.ebuild:
   Marking djview-4.8 ppc for bug 414369
diff --git a/app-text/djview/djview-4.8.ebuild b/app-text/djview/djview-4.8.ebuild
index ca79d1ec51ed..f6ed621f2c38 100644
--- a/app-text/djview/djview-4.8.ebuild
+++ b/app-text/djview/djview-4.8.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/djview/djview-4.8.ebuild,v 1.7 2012/06/07 18:47:39 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/djview/djview-4.8.ebuild,v 1.8 2012/08/20 23:43:23 jer Exp $
 
 EAPI=4
 
@@ -19,7 +19,7 @@ IUSE="debug nsplugin"
 
 RDEPEND="
 	>=app-text/djvu-3.5.22-r1
-	x11-libs/qt-gui:4"
+	x11-libs/qt-gui:4[dbus]"
 DEPEND="${RDEPEND}
 	>=sys-devel/autoconf-2.67
 	virtual/pkgconfig
diff --git a/app-text/djview/djview-4.9.ebuild b/app-text/djview/djview-4.9.ebuild
new file mode 100644
index 000000000000..f98658ed6867
--- /dev/null
+++ b/app-text/djview/djview-4.9.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/djview/djview-4.9.ebuild,v 1.1 2012/08/20 23:43:23 jer Exp $
+
+EAPI=4
+
+inherit autotools gnome2-utils fdo-mime flag-o-matic versionator toolchain-funcs multilib nsplugins
+
+MY_P=${PN}-$(replace_version_separator 2 '-')
+
+DESCRIPTION="Portable DjVu viewer using Qt4"
+HOMEPAGE="http://djvu.sourceforge.net/djview4.html"
+SRC_URI="mirror://sourceforge/djvu/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="debug nsplugin"
+
+RDEPEND="
+	>=app-text/djvu-3.5.22-r1
+	x11-libs/qt-gui:4[dbus]"
+DEPEND="${RDEPEND}
+	>=sys-devel/autoconf-2.67
+	virtual/pkgconfig
+	nsplugin? ( dev-libs/glib:2 )"
+
+S=${WORKDIR}/${PN}4-${PV}
+
+src_prepare() {
+	# Force XEmbed instead of Xt-based mainloop (disable Xt autodep)
+	sed -e 's:\(ac_xt=\)yes:\1no:' -i configure* || die
+	sed 's/AC_CXX_OPTIMIZE/OPTS=;AC_SUBST(OPTS)/' -i configure.ac || die #263688
+	rm aclocal.m4 config/{libtool.m4,install-sh,ltmain.sh,lt*.m4}
+	AT_M4DIR="config" eautoreconf
+}
+
+src_configure() {
+	# See config/acinclude.m4
+	use debug || append-cppflags "-DNDEBUG"
+
+	# QTDIR is needed because of kde3
+	QTDIR=/usr \
+	econf \
+		--with-x \
+		$(use_enable nsplugin nsdejavu) \
+		--disable-desktopfiles
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" \
+		plugindir=/usr/$(get_libdir)/${PLUGINS_DIR} \
+			install
+
+	dodoc README NEWS
+
+	cd desktopfiles
+	insinto /usr/share/icons/hicolor/32x32/apps
+	newins hi32-djview4.png djvulibre-djview4.png
+	insinto /usr/share/icons/hicolor/64x64/apps
+	newins hi64-djview4.png djvulibre-djview4.png
+	insinto /usr/share/icons/hicolor/scalable/apps
+	newins djview.svg djvulibre-djview4.svg
+	domenu djvulibre-djview4.desktop
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}