Version bump for Gnome 3.12.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

3 files changed, 106 insertions, 3 deletions

diff --git a/app-text/evince/ChangeLog b/app-text/evince/ChangeLog
index f4ac1fb2af5b..79f9ae8234fd 100644
--- a/app-text/evince/ChangeLog
+++ b/app-text/evince/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/evince
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v 1.269 2014/04/23 20:55:09 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v 1.270 2014/04/27 15:48:32 eva Exp $
+
+*evince-3.12.1 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@gentoo.org> +evince-3.12.1.ebuild,
+  metadata.xml:
+  Version bump for Gnome 3.12.
 
   23 Apr 2014; Pacho Ramos <pacho@gentoo.org> -evince-3.8.3.ebuild:
   Drop old
diff --git a/app-text/evince/evince-3.12.1.ebuild b/app-text/evince/evince-3.12.1.ebuild
new file mode 100644
index 000000000000..109230982310
--- /dev/null
+++ b/app-text/evince/evince-3.12.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/evince/evince-3.12.1.ebuild,v 1.1 2014/04/27 15:48:32 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="Simple document viewer for GNOME"
+HOMEPAGE="http://www.gnome.org/projects/evince/"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+# subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
+SLOT="0/evd3.4-evv3.3"
+IUSE="debug djvu dvi +introspection libsecret nautilus +postscript t1lib tiff xps"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x64-solaris"
+
+# Since 2.26.2, can handle poppler without cairo support. Make it optional ?
+# not mature enough
+# atk used in libview
+# gdk-pixbuf used all over the place
+# libX11 used for totem-screensaver
+COMMON_DEPEND="
+	dev-libs/atk
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/libxml2-2.5:2
+	sys-libs/zlib:=
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.8:3[introspection?]
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/cairo-1.10:=
+	>=app-text/poppler-0.24:=[cairo]
+	djvu? ( >=app-text/djvu-3.5.17:= )
+	dvi? (
+		virtual/tex-base
+		dev-libs/kpathsea:=
+		t1lib? ( >=media-libs/t1lib-5:= ) )
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+	libsecret? ( >=app-crypt/libsecret-0.5 )
+	nautilus? ( >=gnome-base/nautilus-2.91.4[introspection?] )
+	postscript? ( >=app-text/libspectre-0.2:= )
+	tiff? ( >=media-libs/tiff-3.6:0= )
+	xps? ( >=app-text/libgxps-0.2.1:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/librsvg
+	|| (
+		>=x11-themes/gnome-icon-theme-2.17.1
+		>=x11-themes/hicolor-icon-theme-0.10 )
+	x11-themes/gnome-icon-theme-symbolic
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.3
+	dev-util/gdbus-codegen
+	sys-devel/gettext
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+"
+
+# Needs dogtail and pyspi from http://fedorahosted.org/dogtail/
+# Releases: http://people.redhat.com/zcerza/dogtail/releases/
+RESTRICT="test"
+
+src_prepare() {
+	# ???
+	ELTCONF="--portage"
+
+	gnome2_src_prepare
+
+	# Do not depend on gnome-icon-theme, bug #326855, #391859
+	sed -e 's/gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED//g' \
+		-i configure || die "sed failed"
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-tests \
+		--enable-pdf \
+		--enable-comics \
+		--enable-thumbnailer \
+		--with-platform=gnome \
+		--enable-dbus \
+		$(use_enable djvu) \
+		$(use_enable dvi) \
+		$(use_with libsecret keyring) \
+		$(use_enable introspection) \
+		$(use_enable nautilus) \
+		$(use_enable postscript ps) \
+		$(use_enable t1lib) \
+		$(use_enable tiff) \
+		$(use_enable xps) \
+		ITSTOOL=$(type -P true)
+}
diff --git a/app-text/evince/metadata.xml b/app-text/evince/metadata.xml
index 935f7b26b634..3fba559b909b 100644
--- a/app-text/evince/metadata.xml
+++ b/app-text/evince/metadata.xml
@@ -4,12 +4,12 @@
 	<herd>gnome</herd>
 	<use>
 		<flag name="gnome">Enable the use of <pkg>gnome-base/gconf</pkg> to honour
-		lockdown settings</flag>
+			lockdown settings</flag>
 		<flag name="dvi">Enable the built-in DVI viewer</flag>
 		<flag name="libsecret">Enable support for credentials store</flag>
 		<flag name="nautilus">Enable property page extension in <pkg>gnome-base/nautilus</pkg></flag>
 		<flag name="t1lib">Enable the Type-1 fonts for the built-in DVI viewer
-    (<pkg>media-libs/t1lib</pkg>)</flag>
+			(<pkg>media-libs/t1lib</pkg>)</flag>
 		<flag name="xps">Enable XPS viewer using <pkg>app-text/libgxps</pkg></flag>
 	</use>
 </pkgmetadata>