Bump to latest and use the switches i added upstream. Remove broken one.

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-cpp/libcmis/libcmis-0.2.3.ebuild b/dev-cpp/libcmis/libcmis-0.2.3.ebuild
new file mode 100644
index 000000000000..a612fd9a2a92
--- /dev/null
+++ b/dev-cpp/libcmis/libcmis-0.2.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libcmis/libcmis-0.2.3.ebuild,v 1.1 2012/06/14 08:41:31 scarabeus Exp $
+
+EAPI=4
+
+EGIT_REPO_URI="git://gitorious.org/libcmis/libcmis.git"
+[[ ${PV} == 9999 ]] && SCM_ECLASS="git-2"
+inherit autotools ${SCM_ECLASS}
+unset SCM_ECLASS
+
+DESCRIPTION="C++ client library for the CMIS interface"
+HOMEPAGE="https://sourceforge.net/projects/libcmis/"
+[[ ${PV} == 9999 ]] || SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
+SLOT="0"
+[[ ${PV} == 9999 ]] || KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs man test"
+
+RDEPEND="
+	dev-libs/boost
+	dev-libs/libxml2
+	net-misc/curl
+"
+DEPEND="${RDEPEND}
+	man? ( app-text/docbook2X )
+	test? ( dev-util/cppunit )
+"
+
+# It fetches the apache chemistry webapp and then try to run some magic on it
+RESTRICT="test"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_with man) \
+		$(use_enable static-libs static) \
+		$(use_enable test tests) \
+		--enable-client
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}