Version bump to latest.

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 8EEE3BE8)

3 files changed, 77 insertions, 4 deletions

diff --git a/dev-cpp/libcmis/ChangeLog b/dev-cpp/libcmis/ChangeLog
index c067f7b064cb..dbc17c0095fc 100644
--- a/dev-cpp/libcmis/ChangeLog
+++ b/dev-cpp/libcmis/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-cpp/libcmis
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libcmis/ChangeLog,v 1.23 2013/01/12 13:35:55 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libcmis/ChangeLog,v 1.24 2013/01/31 15:34:17 scarabeus Exp $
+
+*libcmis-0.3.1 (31 Jan 2013)
+
+  31 Jan 2013; Tomáš Chvátal <scarabeus@gentoo.org> +libcmis-0.3.1.ebuild,
+  libcmis-9999.ebuild:
+  Version bump to latest.
 
   12 Jan 2013; Sergey Popov <pinkbyte@gentoo.org> libcmis-0.3.0.ebuild,
   libcmis-9999.ebuild:
diff --git a/dev-cpp/libcmis/libcmis-0.3.1.ebuild b/dev-cpp/libcmis/libcmis-0.3.1.ebuild
new file mode 100644
index 000000000000..38ad3fe966ce
--- /dev/null
+++ b/dev-cpp/libcmis/libcmis-0.3.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libcmis/libcmis-0.3.1.ebuild,v 1.1 2013/01/31 15:34:17 scarabeus Exp $
+
+EAPI=5
+
+EGIT_REPO_URI="git://gitorious.org/libcmis/libcmis.git"
+[[ ${PV} == 9999 ]] && SCM_ECLASS="git-2"
+inherit eutils alternatives autotools ${SCM_ECLASS}
+unset SCM_ECLASS
+
+DESCRIPTION="C++ client library for the CMIS interface"
+HOMEPAGE="https://sourceforge.net/projects/libcmis/"
+[[ ${PV} == 9999 ]] || SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
+SLOT="0.3"
+
+# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="static-libs man test"
+
+RDEPEND="
+	!dev-cpp/libcmis:0
+	dev-libs/boost
+	dev-libs/libxml2
+	net-misc/curl
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	man? (
+		app-text/docbook2X
+		dev-libs/libxslt
+	)
+	test? ( dev-util/cppunit )
+"
+
+src_prepare() {
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--program-suffix=-${SLOT} \
+		--disable-werror \
+		$(use_with man) \
+		$(use_enable static-libs static) \
+		$(use_enable test tests) \
+		--disable-long-tests \
+		--enable-client
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
+
+pkg_postinst() {
+	alternatives_auto_makesym /usr/bin/cmis-client "/usr/bin/cmis-client-[0-9].[0-9]"
+}
+
+pkg_postrm() {
+	alternatives_auto_makesym /usr/bin/cmis-client "/usr/bin/cmis-client-[0-9].[0-9]"
+}
diff --git a/dev-cpp/libcmis/libcmis-9999.ebuild b/dev-cpp/libcmis/libcmis-9999.ebuild
index 3232bc1394e6..2dc16fb39c2c 100644
--- a/dev-cpp/libcmis/libcmis-9999.ebuild
+++ b/dev-cpp/libcmis/libcmis-9999.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libcmis/libcmis-9999.ebuild,v 1.9 2013/01/12 13:35:55 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libcmis/libcmis-9999.ebuild,v 1.10 2013/01/31 15:34:17 scarabeus Exp $
 
-EAPI=4
+EAPI=5
 
 EGIT_REPO_URI="git://gitorious.org/libcmis/libcmis.git"
 [[ ${PV} == 9999 ]] && SCM_ECLASS="git-2"
@@ -18,7 +18,7 @@ SLOT="0.3"
 
 # Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
 [[ ${PV} == 9999 ]] || \
-KEYWORDS="amd64 ~arm ppc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
 
 IUSE="static-libs man test"