Revbump to respect LDFLAGS. Thanks to Diego E. Pettenò <flameeyes@gentoo.org> for the help.

Drop -Werror from the Makefile.

(Portage version: 2.2_rc70/cvs/Linux x86_64)

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-java/libmatthew-java/libmatthew-java-0.7.2-r1.ebuild b/dev-java/libmatthew-java/libmatthew-java-0.7.2-r1.ebuild
new file mode 100644
index 000000000000..d80342dda65d
--- /dev/null
+++ b/dev-java/libmatthew-java/libmatthew-java-0.7.2-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/libmatthew-java/libmatthew-java-0.7.2-r1.ebuild,v 1.1 2010/08/30 16:17:36 serkan Exp $
+
+JAVA_PKG_IUSE="doc source"
+inherit eutils java-pkg-2 flag-o-matic toolchain-funcs
+
+DESCRIPTION="A selection of libraries for Java"
+HOMEPAGE="http://www.matthew.ath.cx/projects/java/"
+SRC_URI="http://www.matthew.ath.cx/projects/java/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND=">=virtual/jre-1.5"
+DEPEND=">=virtual/jdk-1.5"
+
+src_unpack() {
+	unpack ${A}
+	epatch "${FILESDIR}"/${P}-makefile-fixes.patch
+	rm -v "${S}"/cx/ath/matthew/debug/Debug.java || die "rm failed"
+}
+
+src_compile() {
+	CC=$(tc-getCC) LD=$(tc-getCC) INCLUDES="$(java-pkg_get-jni-cflags)" \
+		emake -j1 JARDIR=/usr/share/libmatthew-java/lib JCFLAGS="$(java-pkg_javac-args)" all $(usev doc) || die "emake failed"
+}
+
+src_install() {
+	java-pkg_newjar cgi-0.5.jar cgi.jar
+	java-pkg_newjar debug-disable-1.1.jar debug-disable.jar
+	java-pkg_newjar debug-enable-1.1.jar debug-enable.jar
+	java-pkg_newjar hexdump-0.2.jar hexdump.jar
+	java-pkg_newjar io-0.1.jar io.jar
+	java-pkg_newjar unix-0.5.jar unix.jar
+	java-pkg_doso libcgi-java.so
+	java-pkg_doso libunix-java.so
+	dodoc INSTALL changelog README || die
+	use source && java-pkg_dosrc cx/
+	use doc && java-pkg_dojavadoc doc
+}