Update to python-r1.eclass. Add a patch for cleaner multiple python ABI support.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

4 files changed, 140 insertions, 3 deletions

diff --git a/dev-libs/libxslt/ChangeLog b/dev-libs/libxslt/ChangeLog
index aa4808d6bdc9..8b9f627d2326 100644
--- a/dev-libs/libxslt/ChangeLog
+++ b/dev-libs/libxslt/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/libxslt
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxslt/ChangeLog,v 1.246 2012/11/29 13:23:08 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxslt/ChangeLog,v 1.247 2012/12/18 07:48:47 tetromino Exp $
+
+*libxslt-1.1.28-r1 (18 Dec 2012)
+
+  18 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  libxslt-1.1.28.ebuild, +libxslt-1.1.28-r1.ebuild,
+  +files/libxslt-1.1.28-manual-python.patch:
+  Update to python-r1.eclass. Add a patch for cleaner multiple python ABI
+  support.
 
   29 Nov 2012; Samuli Suominen <ssuominen@gentoo.org>
   -files/libxslt-1.1.23-parallel-install.patch, -libxslt-1.1.26-r3.ebuild,
diff --git a/dev-libs/libxslt/files/libxslt-1.1.28-manual-python.patch b/dev-libs/libxslt/files/libxslt-1.1.28-manual-python.patch
new file mode 100644
index 000000000000..019f3253d876
--- /dev/null
+++ b/dev-libs/libxslt/files/libxslt-1.1.28-manual-python.patch
@@ -0,0 +1,36 @@
+From 1671e1004e18fa9bbce410050d1365374ececb6a Mon Sep 17 00:00:00 2001
+From: Alexandre Rostovtsev <tetromino@gentoo.org>
+Date: Tue, 18 Dec 2012 02:22:47 -0500
+Subject: [PATCH] build/test/install python bindings manually
+
+To support building for multiple python ABIs, we want to skip checks for
+python in configure, and build/test/install python bindings manually.
+---
+ configure.in | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/configure.in b/configure.in
+index fc8d5a8..6312c37 100644
+--- a/configure.in
++++ b/configure.in
+@@ -296,7 +296,7 @@ PYTHON_INCLUDES=
+ PYTHON_SITE_PACKAGES=
+ pythondir=
+ AC_ARG_WITH(python, [  --with-python[=DIR]    Build Python bindings if found])
+-if test "$with_python" != "no" ; then
++if false ; then
+     if test -x "$with_python/bin/python"
+     then
+         echo Found python in $with_python/bin/python
+@@ -365,7 +365,7 @@ except: print 0"`
+         pythondir='$(libdir)/python$(PYTHON_VERSION)/site-packages'
+     fi
+ fi
+-AM_CONDITIONAL(WITH_PYTHON, test "$PYTHON_INCLUDES" != "")
++AM_CONDITIONAL(WITH_PYTHON, test "$with_python" != "no")
+ if test "$PYTHON_INCLUDES" != ""
+ then
+     PYTHON_SUBDIR=python
+-- 
+1.8.0.2
+
diff --git a/dev-libs/libxslt/libxslt-1.1.28-r1.ebuild b/dev-libs/libxslt/libxslt-1.1.28-r1.ebuild
new file mode 100644
index 000000000000..93a7ce1b5807
--- /dev/null
+++ b/dev-libs/libxslt/libxslt-1.1.28-r1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxslt/libxslt-1.1.28-r1.ebuild,v 1.1 2012/12/18 07:48:47 tetromino Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+PYTHON_REQ_USE="xml"
+
+inherit autotools eutils python-r1 toolchain-funcs
+
+DESCRIPTION="XSLT libraries and tools"
+HOMEPAGE="http://www.xmlsoft.org/"
+SRC_URI="ftp://xmlsoft.org/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="crypt debug python static-libs"
+
+RDEPEND=">=dev-libs/libxml2-2.8.0:2
+	crypt?  ( >=dev-libs/libgcrypt-1.1.42:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/libxml2:2[python,${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=684621
+	epatch "${FILESDIR}"/${PN}.m4-${PN}-1.1.26.patch
+
+	epatch "${FILESDIR}"/${PN}-1.1.26-disable_static_modules.patch
+
+	# Python bindings are built/tested/installed manually.
+	epatch "${FILESDIR}"/${PN}-1.1.28-manual-python.patch
+
+	eautoreconf
+	epunt_cxx
+}
+
+src_configure() {
+	# libgcrypt is missing pkg-config file, so fixing cross-compile
+	# here. see bug 267503.
+	tc-is-cross-compiler && \
+		export LIBGCRYPT_CONFIG="${SYSROOT}"/usr/bin/libgcrypt-config
+
+	econf \
+		$(use_enable static-libs static) \
+		--with-html-dir=/usr/share/doc/${PF} \
+		--with-html-subdir=html \
+		$(use_with crypt crypto) \
+		$(use_with python) \
+		$(use_with debug) \
+		$(use_with debug mem-debug)
+}
+
+src_compile() {
+	default
+	if use python; then
+		python_copy_sources
+		python_foreach_impl libxslt_py_emake
+	fi
+}
+
+src_test() {
+	default
+	use python && python_foreach_impl libxslt_py_emake test
+}
+
+src_install() {
+	default
+	dodoc FEATURES
+
+	if use python; then
+		python_foreach_impl libxslt_py_emake DESTDIR="${D}" install
+		python_foreach_impl python_optimize
+		mv "${ED}"/usr/share/doc/${PN}-python-${PV} "${ED}"/usr/share/doc/${PF}/python
+	fi
+
+	prune_libtool_files --modules
+}
+
+libxslt_py_emake() {
+	pushd "${BUILD_DIR}/python" > /dev/null || die
+	emake \
+		PYTHON="${PYTHON}" \
+		PYTHON_INCLUDES="${EPREFIX}/usr/include/${EPYTHON}" \
+		PYTHON_LIBS="$(python-config --ldflags)" \
+		PYTHON_SITE_PACKAGES="$(python_get_sitedir)" \
+		pythondir="$(python_get_sitedir)" \
+		PYTHON_VERSION=${EPYTHON/python} "$@"
+	popd > /dev/null
+}
diff --git a/dev-libs/libxslt/libxslt-1.1.28.ebuild b/dev-libs/libxslt/libxslt-1.1.28.ebuild
index 00c11fa0ea98..548fc3eb2251 100644
--- a/dev-libs/libxslt/libxslt-1.1.28.ebuild
+++ b/dev-libs/libxslt/libxslt-1.1.28.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxslt/libxslt-1.1.28.ebuild,v 1.1 2012/11/29 13:20:30 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxslt/libxslt-1.1.28.ebuild,v 1.2 2012/12/18 07:48:47 tetromino Exp $
 
 EAPI=5
 
@@ -20,7 +20,7 @@ KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~spar
 IUSE="crypt debug python static-libs"
 
 RDEPEND=">=dev-libs/libxml2-2.8.0
-	crypt?  ( >=dev-libs/libgcrypt-1.1.42 )"
+	crypt?  ( >=dev-libs/libgcrypt-1.1.42:= )"
 DEPEND="${RDEPEND}"
 
 DOCS="AUTHORS ChangeLog FEATURES NEWS README TODO"