Version bump, bug 471576

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B427ABC8)

2 files changed, 58 insertions, 1 deletions

diff --git a/dev-libs/libxdg-basedir/ChangeLog b/dev-libs/libxdg-basedir/ChangeLog
index c16284be0cb0..fc8e9bcdcbbd 100644
--- a/dev-libs/libxdg-basedir/ChangeLog
+++ b/dev-libs/libxdg-basedir/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libxdg-basedir
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxdg-basedir/ChangeLog,v 1.35 2014/01/25 03:55:12 creffett Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxdg-basedir/ChangeLog,v 1.36 2014/04/15 19:20:07 idl0r Exp $
+
+*libxdg-basedir-1.2.0 (15 Apr 2014)
+
+  15 Apr 2014; Christian Ruppert <idl0r@gentoo.org>
+  +libxdg-basedir-1.2.0.ebuild:
+  Version bump, bug 471576
 
   25 Jan 2014; Chris Reffett <creffett@gentoo.org> libxdg-basedir-1.1.1.ebuild:
   EAPI bump, remove unneeded || die
diff --git a/dev-libs/libxdg-basedir/libxdg-basedir-1.2.0.ebuild b/dev-libs/libxdg-basedir/libxdg-basedir-1.2.0.ebuild
new file mode 100644
index 000000000000..6bc18d6555d8
--- /dev/null
+++ b/dev-libs/libxdg-basedir/libxdg-basedir-1.2.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxdg-basedir/libxdg-basedir-1.2.0.ebuild,v 1.1 2014/04/15 19:20:07 idl0r Exp $
+
+EAPI=5
+inherit autotools
+
+TREE="9642bf6c996ea1a4b20537db592e96d1c65affe5"
+
+DESCRIPTION="Small library to access XDG Base Directories Specification paths"
+HOMEPAGE="http://repo.or.cz/w/libxdg-basedir.git"
+SRC_URI="http://repo.or.cz/w/libxdg-basedir.git/snapshot/${TREE}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x64-macos ~x86-solaris"
+IUSE="doc static-libs"
+
+RDEPEND=""
+DEPEND="doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable static-libs static) \
+		$(use_enable doc doxygen-html)
+}
+
+src_compile() {
+	emake
+
+	if use doc; then
+		emake doxygen-doc
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use doc; then
+		dohtml -r doc/html/*
+	fi
+
+	find "${D}" -type f -name '*.la' -delete
+}