version bump. kde 4.3 dep.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 88 insertions, 1 deletions

diff --git a/dev-libs/soprano/ChangeLog b/dev-libs/soprano/ChangeLog
index 4376ff88a267..ba3f0bb8c5f9 100644
--- a/dev-libs/soprano/ChangeLog
+++ b/dev-libs/soprano/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/soprano
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/ChangeLog,v 1.21 2009/06/28 23:08:40 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/ChangeLog,v 1.22 2009/08/04 05:27:04 wired Exp $
+
+*soprano-2.3.0 (04 Aug 2009)
+
+  04 Aug 2009; Alex Alexander <wired@gentoo.org> +soprano-2.3.0.ebuild:
+  version bump. kde 4.3 dep.
 
 *soprano-2.2.4 (28 Jun 2009)
 
diff --git a/dev-libs/soprano/soprano-2.3.0.ebuild b/dev-libs/soprano/soprano-2.3.0.ebuild
new file mode 100644
index 000000000000..682428d602c0
--- /dev/null
+++ b/dev-libs/soprano/soprano-2.3.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/soprano-2.3.0.ebuild,v 1.1 2009/08/04 05:27:04 wired Exp $
+
+EAPI="2"
+
+JAVA_PKG_OPT_USE="java"
+inherit base cmake-utils flag-o-matic java-pkg-opt-2
+
+DESCRIPTION="Library that provides a nice QT interface to RDF storage solutions"
+HOMEPAGE="http://sourceforge.net/projects/soprano"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+SLOT="0"
+IUSE="+clucene +dbus debug doc elibc_FreeBSD java +raptor +redland"
+
+COMMON_DEPEND="
+	x11-libs/qt-core:4
+	clucene? ( dev-cpp/clucene )
+	dbus? ( x11-libs/qt-dbus:4 )
+	raptor? ( >=media-libs/raptor-1.4.16 )
+	redland? (
+		>=dev-libs/rasqal-0.9.15
+		>=dev-libs/redland-1.0.6
+	)
+	java? ( >=virtual/jdk-1.6.0 )
+"
+
+DEPEND="${COMMON_DEPEND}
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="${COMMON_DEPEND}
+"
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+pkg_setup() {
+	java-pkg-opt-2_pkg_setup
+	if ! use redland && ! use java ; then
+		ewarn "You explicitly disabled default soprano backend and haven't chosen other one."
+		ewarn "Applications using soprano may need at least one backend functional."
+		ewarn "If you experience any problems, enable any of those USE flags:"
+		ewarn "redland, java"
+	fi
+}
+
+src_prepare() {
+	base_src_prepare
+}
+
+src_configure() {
+	# Fix for missing pthread.h linking
+	# NOTE: temporarily fix until a better cmake files patch will be provided.
+	use elibc_FreeBSD && append-ldflags "-lpthread"
+
+	mycmakeargs="${mycmakeargs}
+		-DSOPRANO_BUILD_TESTS=OFF
+		-DCMAKE_SKIP_RPATH=OFF
+		$(cmake-utils_use !clucene SOPRANO_DISABLE_CLUCENE_INDEX)
+		$(cmake-utils_use !dbus SOPRANO_DISABLE_DBUS)
+		$(cmake-utils_use !raptor SOPRANO_DISABLE_RAPTOR_PARSER)
+		$(cmake-utils_use !redland SOPRANO_DISABLE_REDLAND_BACKEND)
+		$(cmake-utils_use !java SOPRANO_DISABLE_SESAME2_BACKEND)
+		$(cmake-utils_use doc SOPRANO_BUILD_API_DOCS)
+	"
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_test() {
+	mycmakeargs="${mycmakeargs}
+		-DSOPRANO_BUILD_TESTS=ON"
+	cmake-utils_src_configure
+	cmake-utils_src_compile
+	ctest --extra-verbose || die "Tests failed."
+}