bump; rm old, update deps & test phase

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

3 files changed, 57 insertions, 63 deletions

diff --git a/dev-python/apptools/ChangeLog b/dev-python/apptools/ChangeLog
index ffcf167e0f9f..8b2377737e0c 100644
--- a/dev-python/apptools/ChangeLog
+++ b/dev-python/apptools/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/apptools
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/apptools/ChangeLog,v 1.23 2013/05/14 09:57:05 idella4 Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apptools/ChangeLog,v 1.24 2014/05/02 04:22:47 idella4 Exp $
+
+*apptools-4.2.1 (02 May 2014)
+
+  02 May 2014; Ian Delaney <idella4@gentoo.org> +apptools-4.2.1.ebuild,
+  -apptools-4.2.0.ebuild:
+  bump; rm old, update deps & test phase
 
   14 May 2013; Ian Delaney <idella4@gentoo.org> -apptools-4.0.0.ebuild,
   -apptools-4.0.1.ebuild, -apptools-4.1.0.ebuild:
diff --git a/dev-python/apptools/apptools-4.2.0.ebuild b/dev-python/apptools/apptools-4.2.0.ebuild
deleted file mode 100644
index cfe2dadfeea5..000000000000
--- a/dev-python/apptools/apptools-4.2.0.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/apptools/apptools-4.2.0.ebuild,v 1.1 2013/04/03 07:56:26 patrick Exp $
-
-EAPI=4
-
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* *-jython"
-DISTUTILS_SRC_TEST="nosetests"
-
-inherit distutils virtualx eutils
-
-DESCRIPTION="Enthought Tool Suite: Application tools"
-HOMEPAGE="http://code.enthought.com/projects/app_tools/ http://pypi.python.org/pypi/apptools"
-SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples test"
-
-RDEPEND="dev-python/configobj
-	dev-python/numpy
-	>=dev-python/traits-4"
-DEPEND="dev-python/setuptools
-	doc? ( dev-python/sphinx )
-	test? (
-		${RDEPEND}
-		>=dev-python/pyface-4
-		media-fonts/font-cursor-misc
-		media-fonts/font-misc-misc
-		sci-visualization/mayavi
-	)"
-
-src_prepare() {
-	distutils_src_prepare
-	epatch "${FILESDIR}"/${PN}_test.patch
-}
-
-src_compile() {
-	distutils_src_compile
-	use doc && emake -C docs html
-}
-
-src_test() {
-	VIRTUALX_COMMAND="python_execute_nosetests" \
-		virtualmake -P '${S}/build-${PYTHON_ABI}/lib:${S}'
-}
-
-src_install() {
-	find -name "*LICENSE*.txt" -delete
-	distutils_src_install
-
-	use doc && dohtml -r docs/build/html/*
-
-	if use examples; then
-		insinto /usr/share/doc/${PF}
-		doins -r examples
-	fi
-}
diff --git a/dev-python/apptools/apptools-4.2.1.ebuild b/dev-python/apptools/apptools-4.2.1.ebuild
new file mode 100644
index 000000000000..1dd8913fee37
--- /dev/null
+++ b/dev-python/apptools/apptools-4.2.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apptools/apptools-4.2.1.ebuild,v 1.1 2014/05/02 04:22:47 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Enthought Tool Suite: Application tools"
+HOMEPAGE="http://code.enthought.com/projects/app_tools/ http://pypi.python.org/pypi/apptools"
+SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/traits-4[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		>=dev-python/pyface-4[${PYTHON_USEDEP}]
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+		sci-visualization/mayavi[${PYTHON_USEDEP}]
+		dev-python/traits[${PYTHON_USEDEP}]
+		dev-python/traitsui[${PYTHON_USEDEP}]
+	)"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	export TMPDIR="${T}"
+	# Ignore test file that imports a long deprecated module of traits
+	VIRTUALX_COMMAND="nosetests -I test_state_pickler.py" virtualmake
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}