Version bump.

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 86 insertions, 1 deletions

diff --git a/dev-python/dbus-python/ChangeLog b/dev-python/dbus-python/ChangeLog
index 1cb0eb8a7914..49c6621b3676 100644
--- a/dev-python/dbus-python/ChangeLog
+++ b/dev-python/dbus-python/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/dbus-python
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/dbus-python/ChangeLog,v 1.123 2013/04/10 19:49:43 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/dbus-python/ChangeLog,v 1.124 2013/05/10 08:21:55 ssuominen Exp $
+
+*dbus-python-1.2.0 (10 May 2013)
+
+  10 May 2013; Samuli Suominen <ssuominen@gentoo.org>
+  +dbus-python-1.2.0.ebuild:
+  Version bump.
 
   10 Apr 2013; Agostino Sarubbo <ago@gentoo.org> dbus-python-1.1.1-r1.ebuild:
   Stable for s390, wrt bug #458992
diff --git a/dev-python/dbus-python/dbus-python-1.2.0.ebuild b/dev-python/dbus-python/dbus-python-1.2.0.ebuild
new file mode 100644
index 000000000000..f73c10e8f635
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/dbus-python/dbus-python-1.2.0.ebuild,v 1.1 2013/05/10 08:21:55 ssuominen Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit eutils python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/DBusBindings http://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="http://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+# API docs generated with epydoc, which is python2-only
+REQUIRED_USE="doc? ( || ( python_targets_python2_6 python_targets_python2_7 ) )"
+
+RDEPEND=">=dev-libs/dbus-glib-0.100:=
+	>=sys-apps/dbus-1.6:=
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		dev-python/docutils[python_targets_python2_6?,python_targets_python2_7?]
+		=dev-python/epydoc-3*[python_targets_python2_6?,python_targets_python2_7?] )
+	test? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )"
+
+src_prepare() {
+	python_copy_sources
+}
+
+src_configure() {
+	configuring() {
+		# epydoc is python2-only, bug #447642
+		local apidocs=--disable-api-docs
+		[[ ${EPYTHON/.*} = "python2" ]] && apidocs=$(use_enable doc api-docs)
+
+		econf \
+			--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+			--disable-html-docs \
+			${apidocs} \
+			PYTHON_LIBS="$(python-config --ldflags)"
+		# configure assumes that ${PYTHON}-config executable exists :/
+	}
+	python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installing() {
+		default
+		[[ ${EPYTHON/.*} = "python2" ]] && use doc && dohtml -r api/*
+	}
+	python_foreach_impl run_in_build_dir installing
+	prune_libtool_files --modules
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}
+
+run_in_build_dir() {
+	pushd "${BUILD_DIR}" > /dev/null || die
+	"$@"
+	popd > /dev/null
+}