Bump

(Portage version: 2.2.14/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 137 insertions, 1 deletions

diff --git a/dev-python/ipython/ChangeLog b/dev-python/ipython/ChangeLog
index f85622e01f84..af15f63c7288 100644
--- a/dev-python/ipython/ChangeLog
+++ b/dev-python/ipython/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/ipython
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.151 2014/12/01 06:05:58 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.152 2014/12/01 08:36:28 patrick Exp $
+
+*ipython-2.3.1 (01 Dec 2014)
+
+  01 Dec 2014; Patrick Lauer <patrick@gentoo.org> +ipython-2.3.1.ebuild:
+  Bump
 
   01 Dec 2014; Patrick Lauer <patrick@gentoo.org> ipython-2.3.0.ebuild:
   Fix dependencies for test phase
diff --git a/dev-python/ipython/ipython-2.3.1.ebuild b/dev-python/ipython/ipython-2.3.1.ebuild
new file mode 100644
index 000000000000..d4ebf6763c9b
--- /dev/null
+++ b/dev-python/ipython/ipython-2.3.1.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-2.3.1.ebuild,v 1.1 2014/12/01 08:36:28 patrick Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+PYTHON_REQ_USE='readline,sqlite'
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="http://ipython.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+
+IUSE="doc examples matplotlib mongodb notebook nbconvert octave qt4 +smp test wxwidgets"
+
+PY2_USEDEP=$(python_gen_usedep python2_7)
+CDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/simplegeneric[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+	mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
+	octave? ( dev-python/oct2py[${PYTHON_USEDEP}] )
+	smp? ( >=dev-python/pyzmq-2.1.11[${PYTHON_USEDEP}] )
+	wxwidgets? ( $(python_gen_cond_dep 'dev-python/wxpython[${PYTHON_USEDEP}]' python2_7) )"
+RDEPEND="${CDEPEND}
+	notebook? (
+		>=www-servers/tornado-3.1[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		>=dev-python/pyzmq-2.1.11[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-libs/mathjax
+	)
+	nbconvert? (
+		>=app-text/pandoc-1.12.1
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+	)
+	qt4? ( || ( dev-python/PyQt4[${PYTHON_USEDEP}] dev-python/pyside[${PYTHON_USEDEP}] )
+		dev-python/pygments[${PYTHON_USEDEP}]
+		>=dev-python/pyzmq-2.1.11[${PYTHON_USEDEP}] )"
+DEPEND="${CDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/mock[${PY2_USEDEP}]
+		>=www-servers/tornado-3.1[${PYTHON_USEDEP}]
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/fabric[${PYTHON_USEDEP}]' python2_7)
+		>=www-servers/tornado-3.1[${PYTHON_USEDEP}]
+	)"
+
+REQUIRED_USE="doc? ( matplotlib mongodb octave )"
+
+PATCHES=( ${FILESDIR}/2.1.0-substitute-files.patch
+	${FILESDIR}/2.1.0-disable-tests.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/rmagic.py || die
+	rm IPython/extensions/octavemagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+src_test() {
+	# virtualx has trouble with parallel runs.
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	distutils_install_for_testing
+	local fail
+	run_tests() {
+		pushd ${TEST_DIR} > /dev/null
+		"${PYTHON}" -m IPython.testing.iptestcontroller --all || fail=1
+		popd > /dev/null
+	}
+	VIRTUALX_COMMAND=run_tests virtualmake
+		[[ ${fail} ]] && die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+	ln -snf "${EPREFIX}"/usr/share/mathjax \
+		"${D}$(python_get_sitedir)"/IPython/html/static/mathjax || die
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "To enable sympyprinting, it's required to emerge sympy"
+	elog "To enable cythonmagic, it's required to emerge cython"
+}