Version bump, add jpeg2k use flag, and add python3_4 support.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 115 insertions, 1 deletions

diff --git a/dev-python/pillow/ChangeLog b/dev-python/pillow/ChangeLog
index 081c2b34f86d..ad12401adecb 100644
--- a/dev-python/pillow/ChangeLog
+++ b/dev-python/pillow/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pillow
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pillow/ChangeLog,v 1.20 2014/01/25 19:18:46 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pillow/ChangeLog,v 1.21 2014/04/03 06:06:05 radhermit Exp $
+
+*pillow-2.4.0 (03 Apr 2014)
+
+  03 Apr 2014; Tim Harder <radhermit@gentoo.org> +pillow-2.4.0.ebuild:
+  Version bump, add jpeg2k use flag, and add python3_4 support.
 
   25 Jan 2014; Mike Gilbert <floppym@gentoo.org> pillow-2.3.0.ebuild:
   Revert accidental change.
diff --git a/dev-python/pillow/pillow-2.4.0.ebuild b/dev-python/pillow/pillow-2.4.0.ebuild
new file mode 100644
index 000000000000..04faea091ebe
--- /dev/null
+++ b/dev-python/pillow/pillow-2.4.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pillow/pillow-2.4.0.ebuild,v 1.1 2014/04/03 06:06:05 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} )
+PYTHON_REQ_USE='tk?'
+
+inherit distutils-r1 eutils
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="https://github.com/python-imaging/Pillow https://pypi.python.org/pypi/Pillow"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="doc examples jpeg jpeg2k lcms scanner test tiff tk truetype webp zlib"
+REQUIRED_USE="test? ( jpeg )"
+
+RDEPEND="
+	truetype? ( media-libs/freetype:2= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:0= )
+	scanner? ( media-gfx/sane-backends:0= )
+	tiff? ( media-libs/tiff:0= )
+	webp? ( media-libs/libwebp:0= )
+	zlib? ( sys-libs/zlib:0= )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx
+		dev-python/sphinx-better-theme
+	)"
+RDEPEND+=" !dev-python/imaging"
+
+S="${WORKDIR}/${MY_P}"
+
+# See _render and _clean in Tests/test_imagefont.py
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Disable all the stuff we don't want.
+	local f
+	for f in jpeg lcms tiff tk webp zlib; do
+		if ! use ${f}; then
+			sed -i -e "s:feature.${f} =:& None #:" setup.py || die
+		fi
+	done
+	if ! use truetype; then
+		sed -i -e 's:feature.freetype =:& None #:' setup.py || die
+	fi
+	if ! use jpeg2k; then
+		sed -i -e 's:feature.jpeg2000 =:& None #:' setup.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+# XXX: split into two ebuilds?
+wrap_phase() {
+	"${@}"
+
+	if use scanner; then
+		cd Sane || die
+		"${@}"
+	fi
+}
+
+python_compile() {
+	wrap_phase distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	"${PYTHON}" selftest.py --installed || die "Tests fail with ${EPYTHON}"
+	"${PYTHON}" Tests/run.py --installed || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	python_doheader libImaging/{Imaging.h,ImPlatform.h}
+
+	wrap_phase distutils-r1_python_install
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	use examples && local EXAMPLES=( Scripts/. )
+
+	distutils-r1_python_install_all
+
+	if use scanner; then
+		docinto sane
+		dodoc Sane/{CHANGES,README,sanedoc.txt}
+	fi
+
+	if use examples && use scanner; then
+		docinto examples/sane
+		dodoc Sane/demo_*.py
+	fi
+}