Version Bump

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

2 files changed, 66 insertions, 1 deletions

diff --git a/dev-python/pylint/ChangeLog b/dev-python/pylint/ChangeLog
index 2798fd91138a..fc27a650cab2 100644
--- a/dev-python/pylint/ChangeLog
+++ b/dev-python/pylint/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pylint
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v 1.131 2015/06/07 09:12:22 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v 1.132 2015/07/02 20:20:41 jlec Exp $
+
+*pylint-1.4.4 (02 Jul 2015)
+
+  02 Jul 2015; Justin Lecher <jlec@gentoo.org> +pylint-1.4.4.ebuild:
+  Version Bump
 
   07 Jun 2015; Markus Meier <maekke@gentoo.org> pylint-1.4.1.ebuild:
   arm stable, bug #540290
diff --git a/dev-python/pylint/pylint-1.4.4.ebuild b/dev-python/pylint/pylint-1.4.4.ebuild
new file mode 100644
index 000000000000..5fb9bb55d7ba
--- /dev/null
+++ b/dev-python/pylint/pylint-1.4.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/pylint-1.4.4.ebuild,v 1.1 2015/07/02 20:20:41 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+RESTRICT="test" # needs pygtk
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="http://www.logilab.org/project/pylint http://pypi.python.org/pypi/pylint"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/logilab-common-0.53.0[${PYTHON_USEDEP}]
+	>=dev-python/astroid-1.3.6[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND} )"
+
+# Usual. Requ'd for impl specific failures in test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile_all() {
+	# selection of straight html triggers a trivial annoying bug, we skirt it
+	use doc && emake -C doc singlehtml
+}
+
+python_test() {
+	# Test suite appears not to work under Python 3.
+	# https://bitbucket.org/logilab/pylint/issue/240/
+	local msg="Test suite broken with ${EPYTHON}"
+	if python_is_python3; then
+		einfo "${msg}"
+		return 0
+	fi
+
+	pytest || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	doman man/{pylint,pyreverse}.1
+	use examples && local EXAMPLES=( examples/. )
+	use doc && local HTML_DOCS=( doc/_build/singlehtml/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	# Optional dependency on "tk" USE flag would break support for Jython.
+	elog "pylint-gui script requires dev-lang/python with \"tk\" USE flag enabled."
+}