Version bump. Possible API break.

(Portage version: 2.1.10.10/cvs/Linux x86_64)

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-python/scimath/scimath-4.0.0.ebuild b/dev-python/scimath/scimath-4.0.0.ebuild
new file mode 100644
index 000000000000..442df902675d
--- /dev/null
+++ b/dev-python/scimath/scimath-4.0.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/scimath/scimath-4.0.0.ebuild,v 1.1 2011/08/03 23:54:04 bicatali Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.* *-jython"
+DISTUTILS_SRC_TEST="nosetests"
+
+inherit distutils virtualx
+
+DESCRIPTION="Enthought Tool Suite: Scientific and mathematical tools"
+HOMEPAGE="http://code.enthought.com/projects/sci_math/ http://pypi.python.org/pypi/scimath"
+SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/traits-4.0
+	>=dev-python/traitsui-4.0
+	sci-libs/scipy"
+DEPEND="dev-python/setuptools
+	doc? ( dev-python/sphinx )
+	test? (
+		${RDEPEND}
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+		x11-apps/xhost
+	)"
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		emake html || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+src_test() {
+	VIRTUALX_COMMAND="distutils_src_test" virtualmake
+}
+
+src_install() {
+	find -name "*LICENSE*.txt" -delete
+	distutils_src_install
+
+	if use doc; then
+		pushd docs/build/html > /dev/null
+		insinto /usr/share/doc/${PF}/html
+		doins -r [a-z]* _static || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+}