Migrate to distutils-r1.

(Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-python/webtest/webtest-1.4.3-r1.ebuild b/dev-python/webtest/webtest-1.4.3-r1.ebuild
new file mode 100644
index 000000000000..fc1977c81fc8
--- /dev/null
+++ b/dev-python/webtest/webtest-1.4.3-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/webtest/webtest-1.4.3-r1.ebuild,v 1.1 2013/02/15 19:36:17 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit distutils-r1
+
+MY_PN="WebTest"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Helper to test WSGI applications"
+HOMEPAGE="http://pythonpaste.org/webtest/ http://pypi.python.org/pypi/WebTest"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/webob-0.9.2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pyquery[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs html || die
+	fi
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	if [[ ${EPYTHON} == python3* ]]; then
+		rm -f "${D}$(python_get_sitedir)"/webtest/lint3.py
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( html/. )
+	distutils-r1_python_install_all
+}