Support python 3.4

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 66 insertions, 1 deletions

diff --git a/dev-util/devhelp/ChangeLog b/dev-util/devhelp/ChangeLog
index 8fa7e123321f..ea6e49813028 100644
--- a/dev-util/devhelp/ChangeLog
+++ b/dev-util/devhelp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/devhelp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v 1.171 2014/07/23 15:15:48 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v 1.172 2014/11/25 13:45:07 pacho Exp $
+
+*devhelp-3.12.1-r1 (25 Nov 2014)
+
+  25 Nov 2014; Pacho Ramos <pacho@gentoo.org> +devhelp-3.12.1-r1.ebuild:
+  Support python 3.4
 
   23 Jul 2014; Agostino Sarubbo <ago@gentoo.org> devhelp-3.12.1.ebuild:
   Stable for x86, wrt bug #512012
diff --git a/dev-util/devhelp/devhelp-3.12.1-r1.ebuild b/dev-util/devhelp/devhelp-3.12.1-r1.ebuild
new file mode 100644
index 000000000000..d2a6a3a8d204
--- /dev/null
+++ b/dev-util/devhelp/devhelp-3.12.1-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/devhelp-3.12.1-r1.ebuild,v 1.1 2014/11/25 13:45:07 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+# gedit-3.8 is python3 only, this also per:
+# https://bugzilla.redhat.com/show_bug.cgi?id=979450
+PYTHON_COMPAT=( python{3_2,3_3,3_4} )
+
+inherit gnome2 python-single-r1 toolchain-funcs
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
+
+LICENSE="GPL-2+"
+SLOT="0/3-1" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="gedit"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
+
+# FIXME: automagic python dependency
+COMMON_DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	>=x11-libs/gtk+-3.9.10:3
+	>=net-libs/webkit-gtk-2:3
+"
+RDEPEND="${COMMON_DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		app-editors/gedit[introspection,python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		x11-libs/gtk+[introspection] )
+	gnome-base/gsettings-desktop-schemas
+"
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+"
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	if ! use gedit ; then
+		sed -e '/SUBDIRS/ s/gedit-plugin//' -i misc/Makefile.{am,in} || die
+	fi
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	# ICC is crazy, silence warnings (bug #154010)
+	if [[ $(tc-getCC) == "icc" ]] ; then
+		myconf="--with-compile-warnings=no"
+	fi
+	gnome2_src_configure ${myconf}
+}