Version bump.

(Portage version: HEAD/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/dev-util/global/ChangeLog b/dev-util/global/ChangeLog
index 67c3f652221a..25f7d96c56f8 100644
--- a/dev-util/global/ChangeLog
+++ b/dev-util/global/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/global
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.60 2010/07/12 17:52:06 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.61 2010/07/19 23:23:27 arfrever Exp $
+
+*global-5.9.1 (19 Jul 2010)
+
+  19 Jul 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +global-5.9.1.ebuild:
+  Version bump.
 
   12 Jul 2010; Christian Faulhammer <fauli@gentoo.org> global-5.9.ebuild:
   stable x86, bug 327481
diff --git a/dev-util/global/global-5.9.1.ebuild b/dev-util/global/global-5.9.1.ebuild
new file mode 100644
index 000000000000..85118880fc42
--- /dev/null
+++ b/dev-util/global/global-5.9.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/global-5.9.1.ebuild,v 1.1 2010/07/19 23:23:27 arfrever Exp $
+
+EAPI="3"
+
+inherit elisp-common
+
+DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources."
+HOMEPAGE="http://www.gnu.org/software/global/global.html"
+SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.gz"
+LICENSE="GPL-3"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="doc vim emacs"
+
+RDEPEND="vim? ( || ( app-editors/vim app-editors/gvim ) )
+	emacs? ( virtual/emacs )"
+DEPEND="${DEPEND}
+	doc? ( app-text/texi2html sys-apps/texinfo )"
+
+SITEFILE="50gtags-gentoo.el"
+
+src_compile() {
+	if use doc; then
+		texi2pdf -q -o doc/global.pdf doc/global.texi
+		texi2html -o doc/global.html doc/global.texi
+	fi
+
+	if use emacs; then
+		elisp-compile *.el || die "elisp-compile failed"
+	fi
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	if use doc; then
+		dohtml doc/global.html
+		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
+	fi
+
+	dodoc AUTHORS FAQ NEWS README THANKS
+
+	insinto /etc
+	doins gtags.conf
+
+	if use vim; then
+		insinto /usr/share/vim/vimfiles/plugin
+		doins gtags.vim
+	fi
+
+	if use emacs; then
+		elisp-install gtags *.{el,elc}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}