version bump (bug #228623)

(Portage version: 2.1.4.4)

1 files changed, 61 insertions, 0 deletions

diff --git a/games-emulation/mednafen/mednafen-0.8.9.ebuild b/games-emulation/mednafen/mednafen-0.8.9.ebuild
new file mode 100644
index 000000000000..cabe1f5de9e8
--- /dev/null
+++ b/games-emulation/mednafen/mednafen-0.8.9.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/mednafen/mednafen-0.8.9.ebuild,v 1.1 2008/06/20 21:29:02 mr_bones_ Exp $
+
+inherit autotools games
+
+DESCRIPTION="An advanced NES, GB/GBC/GBA, TurboGrafx 16/CD, NGPC and Lynx emulator"
+HOMEPAGE="http://mednafen.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa cjk debug jack nls"
+
+RDEPEND="virtual/opengl
+	media-libs/libsndfile
+	dev-libs/libcdio
+	media-libs/libsdl
+	media-libs/sdl-net
+	alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${PN}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e 's:$(datadir)/locale:/usr/share/locale:' \
+		-e 's:$(localedir):/usr/share/locale:' \
+		$(find . -name 'Makefile.*') \
+		|| die 'sed failed'
+	sed -i \
+		-e '/-fomit-frame/d' configure.ac \
+		|| die "sed failed"
+	eautoreconf
+}
+
+src_compile() {
+	egamesconf \
+		--disable-dependency-tracking \
+		$(use_enable alsa) \
+		$(use_enable cjk cjk-fonts) \
+		$(use_enable debug debugger) \
+		$(use_enable jack) \
+		$(use_enable nls) \
+		|| die
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc Documentation/cheats.txt AUTHORS ChangeLog TODO
+	dohtml Documentation/*
+	prepgamesdirs
+}