Version bump to 4.0.2

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A8C8FBCF)

2 files changed, 150 insertions, 1 deletions

diff --git a/games-emulation/dolphin/ChangeLog b/games-emulation/dolphin/ChangeLog
index 58bb09a8a9af..760a4bc864b0 100644
--- a/games-emulation/dolphin/ChangeLog
+++ b/games-emulation/dolphin/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-emulation/dolphin
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/ChangeLog,v 1.19 2014/03/19 03:06:38 twitch153 Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/ChangeLog,v 1.20 2014/05/04 21:47:04 twitch153 Exp $
+
+*dolphin-4.0.2 (04 May 2014)
+
+  04 May 2014; Devan Franchini <twitch153@gentoo.org> +dolphin-4.0.2.ebuild:
+  Version bump to 4.0.2
 
   19 Mar 2014; Devan Franchini <twitch153@gentoo.org> dolphin-9999.ebuild:
   Adds gtest to saved External directories.
diff --git a/games-emulation/dolphin/dolphin-4.0.2.ebuild b/games-emulation/dolphin/dolphin-4.0.2.ebuild
new file mode 100644
index 000000000000..ca50c06c7709
--- /dev/null
+++ b/games-emulation/dolphin/dolphin-4.0.2.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/dolphin-4.0.2.ebuild,v 1.1 2014/05/04 21:47:04 twitch153 Exp $
+
+EAPI=5
+
+WX_GTK_VER="2.9"
+
+inherit cmake-utils eutils pax-utils toolchain-funcs versionator wxwidgets games
+
+SRC_URI="https://github.com/${PN}-emu/${PN}/archive/${PV}.zip"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Gamecube and Wii game emulator"
+HOMEPAGE="https://www.dolphin-emu.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="alsa ao bluetooth doc ffmpeg +lzo openal opengl openmp portaudio pulseaudio"
+
+RESTRICT="mirror"
+
+RDEPEND=">=media-libs/glew-1.6
+	>=media-libs/libsdl-1.2[joystick]
+	<media-libs/libsfml-2.0
+	>=net-libs/miniupnpc-1.8
+	sys-libs/readline
+	x11-libs/libXext
+	x11-libs/libXrandr
+	alsa? ( media-libs/alsa-lib )
+	ao? ( media-libs/libao )
+	bluetooth? ( net-wireless/bluez )
+	ffmpeg? ( virtual/ffmpeg )
+	lzo? ( dev-libs/lzo )
+	openal? ( media-libs/openal )
+	opengl? ( virtual/opengl )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	"
+DEPEND="${RDEPEND}
+	app-arch/zip
+	media-gfx/nvidia-cg-toolkit
+	media-libs/freetype
+	media-libs/libsoundtouch
+	>=sys-devel/gcc-4.6.0
+	x11-libs/wxGTK:2.9
+	"
+
+pkg_pretend() {
+
+	local ver=4.6.0
+	local msg="${PN} needs at least GCC ${ver} set to compile."
+
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		if ! version_is_at_least ${ver} $(gcc-fullversion); then
+			eerror ${msg}
+			die ${msg}
+		fi
+	fi
+
+}
+
+src_prepare() {
+
+	# Remove automatic dependencies to prevent building without flags enabled.
+	if use !alsa; then
+		sed -i -e '^/include(FindALSA/d' CMakeLists.txt || die
+	fi
+	if use !ao; then
+		sed -i -e '/^check_lib(AO/d' CMakeLists.txt || die
+	fi
+	if use !bluetooth; then
+		sed -i -e '/^check_lib(BLUEZ/d' CMakeLists.txt || die
+	fi
+	if use !openal; then
+		sed -i -e '/^include(FindOpenAL/d' CMakeLists.txt || die
+	fi
+	if use !portaudio; then
+		sed -i -e '/CMAKE_REQUIRED_LIBRARIES portaudio/d' CMakeLists.txt || die
+	fi
+	if use !pulseaudio; then
+		sed -i -e '/^check_lib(PULSEAUDIO/d' CMakeLists.txt || die
+	fi
+
+	# Remove ALL the bundled libraries, aside from:
+	# - SOIL: The sources are not public.
+	# - Bochs-disasm: Don't know what it is.
+	# - CLRun: Part of OpenCL
+	# - polarssl: Currently fails the check as is.
+	mv Externals/SOIL . || die
+	mv Externals/Bochs_disasm . || die
+	mv Externals/CLRun . || die
+	mv Externals/polarssl . || die
+	rm -r Externals/* || die
+	mv polarssl Externals || die
+	mv CLRun Externals || die
+	mv Bochs_disasm Externals || die
+	mv SOIL Externals || die
+}
+
+src_configure() {
+
+	local mycmakeargs=(
+		"-DDOLPHIN_WC_REVISION=${PV}"
+		"-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}"
+		"-Dprefix=${GAMES_PREFIX}"
+		"-Ddatadir=${GAMES_DATADIR}/${PN}"
+		"-Dplugindir=$(games_get_libdir)/${PN}"
+		$( cmake-utils_use ffmpeg ENCODE_FRAMEDUMPS )
+		$( cmake-utils_use openmp OPENMP )
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+
+	cmake-utils_src_compile
+}
+
+src_install() {
+
+	cmake-utils_src_install
+
+	dodoc Readme.txt
+	if use doc; then
+		dodoc -r docs/ActionReplay docs/DSP docs/WiiMote
+	fi
+
+	doicon Source/Core/DolphinWX/resources/Dolphin.xpm
+	make_desktop_entry "dolphin-emu" "Dolphin" "Dolphin" "Game;"
+
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	# Add pax markings for hardened systems
+	pax-mark -m "${EPREFIX}"/usr/games/bin/"${PN}"-emu
+
+	if ! use portaudio; then
+		ewarn "If you want microphone capabilities in dolphin-emu, rebuild with"
+		ewarn "USE=\"portaudio\""
+	fi
+}