Bump to 1.2.3. Use SSH_AUTH_SOCK from gnome-keyring, sftp and ftp fixes.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 84 insertions, 1 deletions

diff --git a/gnome-base/gvfs/ChangeLog b/gnome-base/gvfs/ChangeLog
index 740b4fb77198..317c4359a2cb 100644
--- a/gnome-base/gvfs/ChangeLog
+++ b/gnome-base/gvfs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/gvfs
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.67 2009/05/15 09:40:59 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.68 2009/05/18 21:06:24 eva Exp $
+
+*gvfs-1.2.3 (18 May 2009)
+
+  18 May 2009; Gilles Dartiguelongue <eva@gentoo.org> +gvfs-1.2.3.ebuild:
+  Bump to 1.2.3. Use SSH_AUTH_SOCK from gnome-keyring, sftp and ftp fixes.
 
   15 May 2009; Alexis Ballier <aballier@gentoo.org> gvfs-1.2.2.ebuild:
   keyword ~x86-fbsd, bug #269287
diff --git a/gnome-base/gvfs/gvfs-1.2.3.ebuild b/gnome-base/gvfs/gvfs-1.2.3.ebuild
new file mode 100644
index 000000000000..39529e2fefcb
--- /dev/null
+++ b/gnome-base/gvfs/gvfs-1.2.3.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/gvfs-1.2.3.ebuild,v 1.1 2009/05/18 21:06:24 eva Exp $
+
+EAPI="2"
+
+inherit autotools bash-completion gnome2 eutils
+
+DESCRIPTION="GNOME Virtual Filesystem Layer"
+HOMEPAGE="http://www.gnome.org"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~x86 ~x86-fbsd"
+IUSE="archive avahi bluetooth cdda doc fuse gnome gnome-keyring gphoto2 hal samba"
+
+RDEPEND=">=dev-libs/glib-2.19
+	>=sys-apps/dbus-1.0
+	>=net-libs/libsoup-2.25.1[gnome]
+	dev-libs/libxml2
+	net-misc/openssh
+	archive? ( app-arch/libarchive )
+	avahi? ( >=net-dns/avahi-0.6 )
+	bluetooth? (
+		dev-libs/dbus-glib
+		net-wireless/bluez
+		dev-libs/expat )
+	cdda?  (
+		>=sys-apps/hal-0.5.10
+		>=dev-libs/libcdio-0.78.2[-minimal] )
+	fuse? ( sys-fs/fuse )
+	gnome? ( >=gnome-base/gconf-2.0 )
+	gnome-keyring? ( >=gnome-base/gnome-keyring-1.0 )
+	gphoto2? ( >=media-libs/libgphoto2-2.4 )
+	hal? ( >=sys-apps/hal-0.5.10 )
+	samba? ( >=net-fs/samba-3 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.19
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--enable-http
+		--disable-bash-completion
+		$(use_enable archive)
+		$(use_enable avahi)
+		$(use_enable bluetooth obexftp)
+		$(use_enable cdda)
+		$(use_enable fuse)
+		$(use_enable gnome gconf)
+		$(use_enable gphoto2)
+		$(use_enable hal)
+		$(use_enable gnome-keyring keyring)
+		$(use_enable samba)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Conditional patching purely to avoid eautoreconf
+	use gphoto2 && epatch "${FILESDIR}/${P}-gphoto2-stricter-checks.patch"
+	use archive && epatch "${FILESDIR}/${P}-expose-archive-backend.patch"
+	use gphoto2 || use archive && eautoreconf
+}
+
+src_install() {
+	gnome2_src_install
+	use bash-completion && \
+		dobashcompletion programs/gvfs-bash-completion.sh ${PN}
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	use bash-completion && bash-completion_pkg_postinst
+}