Version bump, drop postinst message (use @preserved-rebuild now)

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

2 files changed, 62 insertions, 2 deletions

diff --git a/gnustep-base/gnustep-gui/ChangeLog b/gnustep-base/gnustep-gui/ChangeLog
index 7af2efbf4611..ad385f6ef10c 100644
--- a/gnustep-base/gnustep-gui/ChangeLog
+++ b/gnustep-base/gnustep-gui/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnustep-base/gnustep-gui
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog,v 1.101 2013/04/24 17:33:29 voyageur Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog,v 1.102 2014/01/29 15:12:22 voyageur Exp $
+
+*gnustep-gui-0.24.0 (29 Jan 2014)
+
+  29 Jan 2014; Bernard Cafarelli <voyageur@gentoo.org>
+  +gnustep-gui-0.24.0.ebuild:
+  Version bump, drop postinst message (use @preserved-rebuild now)
 
 *gnustep-gui-0.23.1 (24 Apr 2013)
 
diff --git a/gnustep-base/gnustep-gui/gnustep-gui-0.24.0.ebuild b/gnustep-base/gnustep-gui/gnustep-gui-0.24.0.ebuild
new file mode 100644
index 000000000000..4b15980407bc
--- /dev/null
+++ b/gnustep-base/gnustep-gui/gnustep-gui-0.24.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/gnustep-gui-0.24.0.ebuild,v 1.1 2014/01/29 15:12:22 voyageur Exp $
+
+EAPI=5
+inherit gnustep-base multilib
+
+DESCRIPTION="Library of GUI classes written in Obj-C"
+HOMEPAGE="http://www.gnustep.org/"
+SRC_URI="ftp://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="cups gif jpeg png speech"
+
+DEPEND="${GNUSTEP_CORE_DEPEND}
+	app-text/aspell
+	>=gnustep-base/gnustep-base-1.24.6
+	media-libs/audiofile
+	>=media-libs/tiff-3
+	x11-libs/libXt
+	cups? ( >=net-print/cups-1.1 )
+	gif? ( >=media-libs/giflib-4.1 )
+	jpeg? ( virtual/jpeg )
+	png? ( >=media-libs/libpng-1.2 )
+	speech? ( app-accessibility/flite )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	gnustep-base_src_prepare
+
+	# remove hardcoded -g -Werror, bug #378179
+	sed -i -e 's/-g -Werror//' \
+		Tools/say/GNUmakefile \
+		Tools/speech/GNUmakefile \
+		|| die
+}
+
+src_configure() {
+	egnustep_env
+
+	local myconf=
+	use gif && myconf="--disable-ungif --enable-libgif"
+
+	econf \
+		$(use_enable cups) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable speech) \
+		--with-tiff-include="${EPREFIX}"/usr/include \
+		--with-tiff-library="${EPREFIX}"/usr/$(get_libdir) \
+		${myconf}
+}