Version bump KDE SC 4.14.0

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

2 files changed, 69 insertions, 1 deletions

diff --git a/kde-base/cantor/ChangeLog b/kde-base/cantor/ChangeLog
index c9f01c9f20dc..d8c09c460d0f 100644
--- a/kde-base/cantor/ChangeLog
+++ b/kde-base/cantor/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/cantor
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.181 2014/07/28 08:02:48 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.182 2014/08/20 16:02:53 johu Exp $
+
+*cantor-4.14.0 (20 Aug 2014)
+
+  20 Aug 2014; Johannes Huber <johu@gentoo.org> +cantor-4.14.0.ebuild:
+  Version bump KDE SC 4.14.0
 
   28 Jul 2014; Michael Palimaka <kensington@gentoo.org> cantor-4.13.3.ebuild:
   Only use python eclass when python support is enabled wrt bug #518368.
diff --git a/kde-base/cantor/cantor-4.14.0.ebuild b/kde-base/cantor/cantor-4.14.0.ebuild
new file mode 100644
index 000000000000..856652267df7
--- /dev/null
+++ b/kde-base/cantor/cantor-4.14.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/cantor-4.14.0.ebuild,v 1.1 2014/08/20 16:02:53 johu Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+PYTHON_COMPAT=( python2_7 )
+inherit kde4-base python-single-r1
+
+DESCRIPTION="KDE4 interface for doing mathematics and scientific computing"
+HOMEPAGE="http://www.kde.org/applications/education/cantor http://edu.kde.org/cantor"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="analitza debug postscript python qalculate +R"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
+RDEPEND="
+	analitza? ( $(add_kdebase_dep analitza) )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate
+	)
+	postscript? ( app-text/libspectre )
+	python? ( ${PYTHON_DEPS} )
+	R? ( dev-lang/R )
+	dev-qt/qtxmlpatterns:4
+"
+DEPEND="${RDEPEND}
+	>=dev-cpp/eigen-2.0.3:2
+"
+
+RESTRICT="test"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with analitza)
+		$(cmake-utils_use_with postscript LibSpectre)
+		$(cmake-utils_use_with python PythonLibs)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with R)
+	)
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if ! use analitza && ! use python && ! use qalculate && ! use R; then
+		echo
+		ewarn "You have decided to build ${PN} with no backend."
+		ewarn "To have this application functional, please do one of below:"
+		ewarn "    # emerge -va1 '='${CATEGORY}/${P} with 'analitza', 'python', 'qalculate' or 'R' USE flag enabled"
+		ewarn "    # emerge -vaDu sci-mathematics/maxima"
+		echo
+	fi
+}