Version bump KDE SC 4.14.1

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

2 files changed, 63 insertions, 1 deletions

diff --git a/kde-base/okular/ChangeLog b/kde-base/okular/ChangeLog
index 297a5145f5c3..536646232b9b 100644
--- a/kde-base/okular/ChangeLog
+++ b/kde-base/okular/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/okular
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/okular/ChangeLog,v 1.257 2014/08/20 16:02:52 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/okular/ChangeLog,v 1.258 2014/09/16 18:17:30 johu Exp $
+
+*okular-4.14.1 (16 Sep 2014)
+
+  16 Sep 2014; Johannes Huber <johu@gentoo.org> +okular-4.14.1.ebuild:
+  Version bump KDE SC 4.14.1
 
 *okular-4.14.0 (20 Aug 2014)
 
diff --git a/kde-base/okular/okular-4.14.1.ebuild b/kde-base/okular/okular-4.14.1.ebuild
new file mode 100644
index 000000000000..7103e945320c
--- /dev/null
+++ b/kde-base/okular/okular-4.14.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/okular/okular-4.14.1.ebuild,v 1.1 2014/09/16 18:17:30 johu Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+
+#VIRTUALX_REQUIRED=test
+RESTRICT=test
+# test 2: parttest hangs
+
+inherit kde4-base
+
+DESCRIPTION="Okular is a universal document viewer based on KPDF for KDE 4"
+HOMEPAGE="http://okular.kde.org http://www.kde.org/applications/graphics/okular"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="chm crypt debug djvu dpi ebook +jpeg mobi +postscript +pdf +tiff"
+
+DEPEND="
+	media-libs/freetype
+	media-libs/qimageblitz
+	sys-libs/zlib
+	chm? ( dev-libs/chmlib )
+	crypt? ( app-crypt/qca:2 )
+	djvu? ( app-text/djvu )
+	dpi? ( x11-libs/libkscreen:4 )
+	ebook? ( app-text/ebook-tools )
+	jpeg? (
+		$(add_kdebase_dep libkexiv2)
+		virtual/jpeg:0
+	)
+	mobi? ( $(add_kdebase_dep kdegraphics-mobipocket) )
+	pdf? ( >=app-text/poppler-0.20[qt4,-exceptions(-)] )
+	postscript? ( app-text/libspectre )
+	tiff? ( media-libs/tiff )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with chm)
+		$(cmake-utils_use_with crypt QCA2)
+		$(cmake-utils_use_with djvu DjVuLibre)
+		$(cmake-utils_use_with dpi LibKScreen)
+		$(cmake-utils_use_with ebook EPub)
+		$(cmake-utils_use_with jpeg)
+		$(cmake-utils_use_with jpeg Kexiv2)
+		$(cmake-utils_use_with mobi QMobiPocket)
+		$(cmake-utils_use_with postscript LibSpectre)
+		$(cmake-utils_use_with pdf PopplerQt4)
+		$(cmake-utils_use_with pdf Poppler)
+		$(cmake-utils_use_with tiff)
+	)
+
+	kde4-base_src_configure
+}