version bump for security bug 460818

(Portage version: 2.1.11.52/cvs/Linux x86_64, signed Manifest commit with key 2B6559ED)

2 files changed, 343 insertions, 1 deletions

diff --git a/mail-client/thunderbird/ChangeLog b/mail-client/thunderbird/ChangeLog
index 471b53a393a2..0e2bed00d674 100644
--- a/mail-client/thunderbird/ChangeLog
+++ b/mail-client/thunderbird/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for mail-client/thunderbird
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/thunderbird/ChangeLog,v 1.198 2013/02/24 19:58:34 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/thunderbird/ChangeLog,v 1.199 2013/03/08 21:16:53 axs Exp $
+
+*thunderbird-17.0.4 (08 Mar 2013)
+
+  08 Mar 2013; Ian Stakenvicius <axs@gentoo.org> +thunderbird-17.0.4.ebuild:
+  version bump for security bug 460818
 
   24 Feb 2013; Agostino Sarubbo <ago@gentoo.org> thunderbird-17.0.3.ebuild:
   Stable for arm, wrt bug #458390
diff --git a/mail-client/thunderbird/thunderbird-17.0.4.ebuild b/mail-client/thunderbird/thunderbird-17.0.4.ebuild
new file mode 100644
index 000000000000..576207f609f3
--- /dev/null
+++ b/mail-client/thunderbird/thunderbird-17.0.4.ebuild
@@ -0,0 +1,337 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/thunderbird/thunderbird-17.0.4.ebuild,v 1.1 2013/03/08 21:16:53 axs Exp $
+
+EAPI="3"
+WANT_AUTOCONF="2.1"
+MOZ_ESR="1"
+
+# This list can be updated using scripts/get_langs.sh from the mozilla overlay
+MOZ_LANGS=(ar ast be bg bn-BD br ca cs da de el en en-GB en-US es-AR
+es-ES et eu fi fr fy-NL ga-IE gd gl he hr hu hy-AM id is it ja ko lt nb-NO
+nl nn-NO pa-IN pl pt-BR pt-PT rm ro ru si sk sl sq sr sv-SE ta-LK tr uk vi
+zh-CN zh-TW )
+
+# Convert the ebuild version to the upstream mozilla version, used by mozlinguas
+MOZ_PV="${PV/_beta/b}"
+# ESR releases have slightly version numbers
+if [[ ${MOZ_ESR} == 1 ]]; then
+	MOZ_PV="${MOZ_PV}esr"
+fi
+MOZ_P="${PN}-${MOZ_PV}"
+
+# Enigmail version
+EMVER="1.5.0"
+# Upstream ftp release URI that's used by mozlinguas.eclass
+# We don't use the http mirror because it deletes old tarballs.
+MOZ_FTP_URI="ftp://ftp.mozilla.org/pub/${PN}/releases/"
+
+inherit flag-o-matic toolchain-funcs mozconfig-3 makeedit multilib autotools pax-utils check-reqs nsplugins mozlinguas
+
+DESCRIPTION="Thunderbird Mail Client"
+HOMEPAGE="http://www.mozilla.com/en-US/thunderbird/"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+SLOT="0"
+LICENSE="MPL-2.0 GPL-2 LGPL-2.1"
+IUSE="bindist gconf +crypt +jit +ipc ldap +lightning +minimal mozdom selinux"
+
+PATCH="thunderbird-17.0-patches-01"
+PATCHFF="firefox-17.0-patches-0.4"
+
+SRC_URI="${SRC_URI}
+	${MOZ_FTP_URI}${MOZ_PV}/source/${MOZ_P}.source.tar.bz2
+	crypt? ( http://www.mozilla-enigmail.org/download/source/enigmail-${EMVER}.tar.gz )
+	http://dev.gentoo.org/~anarchy/mozilla/patchsets/${PATCH}.tar.xz
+	http://dev.gentoo.org/~anarchy/mozilla/patchsets/${PATCHFF}.tar.xz
+	http://dev.gentoo.org/~nirbheek/mozilla/patchsets/${PATCHFF}.tar.xz
+	http://dev.gentoo.org/~polynomial-c/mozilla/patchsets/${PATCH}.tar.xz"
+
+ASM_DEPEND=">=dev-lang/yasm-1.1"
+
+RDEPEND=">=sys-devel/binutils-2.16.1
+	>=dev-libs/nss-3.14.1
+	>=dev-libs/nspr-4.9.4
+	>=dev-libs/glib-2.26
+	gconf? ( >=gnome-base/gconf-1.2.1:2 )
+	>=media-libs/libpng-1.5.11[apng]
+	>=x11-libs/cairo-1.10
+	>=x11-libs/pango-1.14.0
+	>=x11-libs/gtk+-2.14
+	kernel_linux? ( media-libs/alsa-lib )
+	>=media-libs/libvpx-1.0.0
+	virtual/libffi
+	!x11-plugins/enigmail
+	system-sqlite? ( >=dev-db/sqlite-3.7.13[fts3,secure-delete,threadsafe,unlock-notify,debug=] )
+	selinux? ( sec-policy/selinux-thunderbird )
+	crypt?  ( || (
+		( >=app-crypt/gnupg-2.0
+			|| (
+				app-crypt/pinentry[gtk]
+				app-crypt/pinentry[qt4]
+			)
+		)
+		=app-crypt/gnupg-1.4*
+	) )"
+
+DEPEND="${RDEPEND}
+	!elibc_glibc? ( dev-libs/libexecinfo )
+	virtual/pkgconfig
+	amd64? ( ${ASM_DEPEND}
+		virtual/opengl )
+	x86? ( ${ASM_DEPEND}
+		virtual/opengl )"
+
+if [[ ${PV} =~ beta ]]; then
+	S="${WORKDIR}/comm-beta"
+elif [[ ${MOZ_ESR} == 1 ]]; then
+	S="${WORKDIR}/comm-esr${PV%%.*}"
+else
+	S="${WORKDIR}/comm-release"
+fi
+
+pkg_setup() {
+	moz_pkgsetup
+
+	export MOZILLA_DIR="${S}/mozilla"
+
+	if ! use bindist ; then
+		elog "You are enabling official branding. You may not redistribute this build"
+		elog "to any users on your network or the internet. Doing so puts yourself into"
+		elog "a legal problem with Mozilla Foundation"
+		elog "You can disable it by emerging ${PN} _with_ the bindist USE-flag"
+		elog
+	fi
+
+	# Ensure we have enough disk space to compile
+	CHECKREQS_DISK_BUILD="4G"
+	check-reqs_pkg_setup
+}
+
+src_unpack() {
+	unpack ${A}
+
+	# Unpack language packs
+	mozlinguas_src_unpack
+}
+
+src_prepare() {
+	# Apply our Thunderbird patchset
+	EPATCH_SUFFIX="patch" \
+	EPATCH_FORCE="yes" \
+	epatch "${WORKDIR}/thunderbird"
+
+	# Apply our patchset from firefox to thunderbird as well
+	pushd "${S}"/mozilla &>/dev/null || die
+	EPATCH_SUFFIX="patch" \
+	EPATCH_FORCE="yes" \
+	epatch "${WORKDIR}/firefox"
+	popd &>/dev/null || die
+
+	if use crypt ; then
+		mv "${WORKDIR}"/enigmail "${S}"/mailnews/extensions/enigmail
+		cd "${S}"
+	fi
+
+	# Disable gnomevfs extension
+	sed -i -e "s:gnomevfs::" "${S}/"mozilla/browser/confvars.sh \
+		-e "s:gnomevfs::" "${S}/"mozilla/xulrunner/confvars.sh \
+		|| die "Failed to remove gnomevfs extension"
+
+	#Fix compilation with curl-7.21.7 bug 376027
+	sed -e '/#include <curl\/types.h>/d'  \
+		-i "${S}"/mozilla/toolkit/crashreporter/google-breakpad/src/common/linux/http_upload.cc \
+		-i "${S}"/mozilla/toolkit/crashreporter/google-breakpad/src/common/linux/libcurl_wrapper.cc \
+		-i "${S}"/mozilla/config/system-headers \
+		-i "${S}"/mozilla/js/src/config/system-headers || die "Sed failed"
+
+	# Don't error out when there's no files to be removed:
+	sed 's@\(xargs rm\)$@\1 -f@' \
+		-i "${S}"/mozilla/toolkit/mozapps/installer/packager.mk || die
+
+	# Shell scripts sometimes contain DOS line endings; bug 391889
+	grep -rlZ --include="*.sh" $'\r$' . |
+	while read -r -d $'\0' file ; do
+		einfo edos2unix "${file}"
+		edos2unix "${file}"
+	done
+
+	# Allow user to apply any additional patches without modifing ebuild
+	epatch_user
+
+	eautoreconf
+	# Ensure we run eautoreconf in mozilla to regenerate configure
+	cd "${S}"/mozilla
+	eautoconf
+}
+
+src_configure() {
+	declare MOZILLA_FIVE_HOME="/usr/$(get_libdir)/${PN}"
+	MEXTENSIONS="default"
+
+	####################################
+	#
+	# mozconfig, CFLAGS and CXXFLAGS setup
+	#
+	####################################
+
+	mozconfig_init
+	mozconfig_config
+
+	# It doesn't compile on alpha without this LDFLAGS
+	use alpha && append-ldflags "-Wl,--no-relax"
+
+	# We must force enable jemalloc 3 threw .mozconfig
+	echo "export MOZ_JEMALLOC=1" >> ${S}/.mozconfig
+
+	mozconfig_annotate '' --prefix="${EPREFIX}"/usr
+	mozconfig_annotate '' --libdir="${EPREFIX}"/usr/$(get_libdir)
+	mozconfig_annotate '' --enable-extensions="${MEXTENSIONS}"
+	mozconfig_annotate '' --with-default-mozilla-five-home="${EPREFIX}${MOZILLA_FIVE_HOME}"
+	mozconfig_annotate '' --with-user-appdir=.thunderbird
+	mozconfig_annotate '' --with-system-png
+	mozconfig_annotate '' --enable-system-ffi
+	mozconfig_annotate '' --target="${CTARGET:-${CHOST}}"
+	mozconfig_annotate '' --build="${CTARGET:-${CHOST}}"
+
+	# Use enable features
+	mozconfig_use_enable lightning calendar
+	mozconfig_use_enable gconf
+	mozconfig_use_enable ldap
+	# Features know to cause problems with hardened.
+	mozconfig_use_enable jit methodjit
+	mozconfig_use_enable jit tracejit
+
+	# Bug #72667
+	if use mozdom; then
+		MEXTENSIONS="${MEXTENSIONS},inspector"
+	fi
+
+	# Use an objdir to keep things organized.
+	echo "mk_add_options MOZ_OBJDIR=@TOPSRCDIR@/tbird" >> "${S}"/.mozconfig
+
+	# Finalize and report settings
+	mozconfig_final
+
+	####################################
+	#
+	#  Configure and build
+	#
+	####################################
+
+	# Disable no-print-directory
+	MAKEOPTS=${MAKEOPTS/--no-print-directory/}
+
+	if [[ $(gcc-major-version) -lt 4 ]]; then
+		append-cxxflags -fno-stack-protector
+	elif [[ $(gcc-major-version) -gt 4 || $(gcc-minor-version) -gt 3 ]]; then
+		if use amd64 || use x86; then
+			append-flags -mno-avx
+		fi
+	fi
+}
+
+src_compile() {
+	CC="$(tc-getCC)" CXX="$(tc-getCXX)" LD="$(tc-getLD)" \
+	MOZ_MAKE_FLAGS="${MAKEOPTS}" \
+	emake -f client.mk || die
+
+	# Only build enigmail extension if crypt enabled.
+	if use crypt ; then
+		cd "${S}"/mailnews/extensions/enigmail || die
+		./makemake -r 2&> /dev/null
+		cd "${S}"/tbird/mailnews/extensions/enigmail
+		emake || die "make enigmail failed"
+		emake xpi || die "make enigmail xpi failed"
+	fi
+}
+
+src_install() {
+	declare MOZILLA_FIVE_HOME="/usr/$(get_libdir)/${PN}"
+	declare emid
+	local obj_dir="tbird"
+	cd "${S}/${obj_dir}"
+
+	# Copy our preference before omnijar is created.
+	cp "${FILESDIR}"/thunderbird-gentoo-default-prefs-1.js-1 \
+		"${S}/${obj_dir}/mozilla/dist/bin/defaults/pref/all-gentoo.js" || die
+
+	# Without methodjit and tracejit there's no conflict with PaX
+	if use jit; then
+		# Pax mark xpcshell for hardened support, only used for startupcache creation.
+		pax-mark m "${S}"/${obj_dir}/mozilla/dist/bin/xpcshell
+	fi
+
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	# Install language packs
+	mozlinguas_src_install
+
+	if ! use bindist; then
+		newicon "${S}"/other-licenses/branding/thunderbird/content/icon48.png thunderbird-icon.png
+		domenu "${FILESDIR}"/icon/${PN}.desktop
+	else
+		newicon "${S}"/mail/branding/aurora/content/icon48.png thunderbird-icon-unbranded.png
+		newmenu "${FILESDIR}"/icon/${PN}-unbranded.desktop \
+			${PN}.desktop
+
+		sed -i -e "s:Mozilla\ Thunderbird:EarlyBird:g" \
+			"${ED}"/usr/share/applications/${PN}.desktop
+	fi
+
+	if use crypt ; then
+		cd "${T}" || die
+		unzip "${S}"/${obj_dir}/mozilla/dist/bin/enigmail*.xpi install.rdf || die
+		emid=$(sed -n '/<em:id>/!d; s/.*\({.*}\).*/\1/; p; q' install.rdf)
+
+		dodir ${MOZILLA_FIVE_HOME}/extensions/${emid} || die
+		cd "${D}"${MOZILLA_FIVE_HOME}/extensions/${emid} || die
+		unzip "${S}"/${obj_dir}/mozilla/dist/bin/enigmail*.xpi || die
+	fi
+
+	if use lightning ; then
+		emid="{a62ef8ec-5fdc-40c2-873c-223b8a6925cc}"
+		dodir ${MOZILLA_FIVE_HOME}/extensions/${emid}
+		cd "${ED}"${MOZILLA_FIVE_HOME}/extensions/${emid}
+		unzip "${S}"/${obj_dir}/mozilla/dist/xpi-stage/gdata-provider.xpi
+
+		emid="calendar-timezones@mozilla.org"
+		dodir ${MOZILLA_FIVE_HOME}/extensions/${emid}
+		cd "${ED}"${MOZILLA_FIVE_HOME}/extensions/${emid}
+		unzip "${S}"/${obj_dir}/mozilla/dist/xpi-stage/calendar-timezones.xpi
+
+		emid="{e2fda1a4-762b-4020-b5ad-a41df1933103}"
+		dodir ${MOZILLA_FIVE_HOME}/extensions/${emid}
+		cd "${ED}"${MOZILLA_FIVE_HOME}/extensions/${emid}
+		unzip "${S}"/${obj_dir}/mozilla/dist/xpi-stage/lightning.xpi
+
+		# Fix mimetype so it shows up as a calendar application in GNOME 3
+		# This requires that the .desktop file was already installed earlier
+		sed -e "s:^\(MimeType=\):\1text/calendar;:" \
+			-e "s:^\(Categories=\):\1Calendar;:" \
+			-i "${ED}"/usr/share/applications/${PN}.desktop
+	fi
+
+	if use jit ; then
+		pax-mark m "${ED}"/${MOZILLA_FIVE_HOME}/{thunderbird-bin,thunderbird}
+	fi
+
+	# Plugin-container needs to be pax-marked for hardened to ensure plugins such as flash
+	# continue to work as expected.
+	pax-mark m "${ED}"${MOZILLA_FIVE_HOME}/plugin-container
+
+	# Plugins dir
+	share_plugins_dir
+
+	if use minimal; then
+		rm -rf "${ED}"/usr/include "${ED}${MOZILLA_FIVE_HOME}"/{idl,include,lib,sdk} || \
+			die "Failed to remove sdk and headers"
+	fi
+}
+
+pkg_postinst() {
+	elog
+	elog "If you are experience problems with plugins please issue the"
+	elog "following command : rm \${HOME}/.thunderbird/*/extensions.sqlite ,"
+	elog "then restart thunderbird"
+}