Revbump fixing bugs #503270 (python-3.x support) and #503124.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x6F48D3DA05C2DADB!)

3 files changed, 63 insertions, 33 deletions

diff --git a/mail-filter/pypolicyd-spf/ChangeLog b/mail-filter/pypolicyd-spf/ChangeLog
index f815bdfea307..48ff87f22415 100644
--- a/mail-filter/pypolicyd-spf/ChangeLog
+++ b/mail-filter/pypolicyd-spf/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for mail-filter/pypolicyd-spf
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/pypolicyd-spf/ChangeLog,v 1.31 2014/03/03 00:17:11 mjo Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/pypolicyd-spf/ChangeLog,v 1.32 2014/05/10 03:28:18 mjo Exp $
+
+*pypolicyd-spf-1.2-r1 (10 May 2014)
+
+  10 May 2014; Michael Orlitzky <mjo@gentoo.org> +pypolicyd-spf-1.2-r1.ebuild,
+  -pypolicyd-spf-1.2.ebuild:
+  Revbump fixing bugs #503270 (python-3.x support) and #503124.
 
 *pypolicyd-spf-1.2 (03 Mar 2014)
 
diff --git a/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2-r1.ebuild b/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2-r1.ebuild
new file mode 100644
index 000000000000..987a5c1a4005
--- /dev/null
+++ b/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2-r1.ebuild,v 1.1 2014/05/10 03:28:18 mjo Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+# With >=python-3.3, the built-in ipaddress module handles the parsing
+# of IP addresses. If python is built without ipv6 support, then
+# ipaddress can't parse ipv6 addresses, and the daemon will crash if it
+# sees an ipv6 SPF record. In other words, it's completely broken.
+#
+# Ideally this would remain optional for python-2.x, but until there's
+# an easy way to do that, "maybe annoying" seems a better option than
+# "maybe broken."
+PYTHON_REQ_USE="ipv6"
+
+inherit distutils-r1 versionator
+
+DESCRIPTION="Python-based policy daemon for Postfix SPF verification"
+HOMEPAGE="https://launchpad.net/pypolicyd-spf"
+SRC_URI="http://launchpad.net/pypolicyd-spf/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# ipaddr is only needed with <python-3.3.
+#
+# The lower version bound is reported at,
+#
+#   https://bugs.launchpad.net/pypolicyd-spf/+bug/1229862
+#
+DEPEND="$(python_gen_cond_dep \
+			'>=dev-python/ipaddr-2.1.10[${PYTHON_USEDEP}]' \
+			'python2*')
+	dev-python/pyspf[${PYTHON_USEDEP}]"
+
+RDEPEND="${DEPEND}
+	dev-python/authres[${PYTHON_USEDEP}]"
+
+DOCS=( CHANGES policyd-spf.conf.commented README README.per_user_whitelisting )
+
+src_prepare() {
+	# The "real" config file mentions the commented one, so we point
+	# users in the right direction.
+	local oldconf="policyd-spf.conf.commented"
+	local newconf="/usr/share/doc/${PF}/${oldconf}"
+
+	sed -i "1 s~ ${oldconf}~,\n#  ${newconf}~" policyd-spf.conf \
+		|| die 'failed to update commented config file path'
+
+	distutils-r1_src_prepare
+}
diff --git a/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2.ebuild b/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2.ebuild
deleted file mode 100644
index 6c7ca47da42b..000000000000
--- a/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2.ebuild
+++ /dev/null
@@ -1,32 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/pypolicyd-spf/pypolicyd-spf-1.2.ebuild,v 1.1 2014/03/03 00:17:11 mjo Exp $
-
-EAPI=5
-
-# >= python-3.2 are also supported, but not until the pyspf ebuilds are
-# updated.
-PYTHON_COMPAT=( python{2_6,2_7} )
-
-inherit distutils-r1 versionator
-
-DESCRIPTION="Python based policy daemon for Postfix SPF checking"
-HOMEPAGE="https://launchpad.net/pypolicyd-spf"
-SRC_URI="http://launchpad.net/pypolicyd-spf/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-# ipaddr is only needed with <python-3.3.
-#
-# The lower version bound is reported at,
-#
-#   https://bugs.launchpad.net/pypolicyd-spf/+bug/1229862
-#
-DEPEND=">=dev-python/ipaddr-2.1.10[${PYTHON_USEDEP}]
-	dev-python/pyspf[${PYTHON_USEDEP}]"
-
-RDEPEND="${DEPEND}
-	dev-python/authres[${PYTHON_USEDEP}]"