Version bump.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 84 insertions, 2 deletions

diff --git a/media-gfx/gmic/ChangeLog b/media-gfx/gmic/ChangeLog
index 90fb82bdae59..3e91c19983d3 100644
--- a/media-gfx/gmic/ChangeLog
+++ b/media-gfx/gmic/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/gmic
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/ChangeLog,v 1.29 2012/12/08 21:22:57 radhermit Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/ChangeLog,v 1.30 2013/01/09 03:05:09 radhermit Exp $
+
+*gmic-1.5.2.5 (09 Jan 2013)
+
+  09 Jan 2013; Tim Harder <radhermit@gentoo.org> +gmic-1.5.2.5.ebuild:
+  Version bump.
 
   08 Dec 2012; Tim Harder <radhermit@gentoo.org>
   files/gmic-1.5.2.2-makefile.patch:
diff --git a/media-gfx/gmic/gmic-1.5.2.5.ebuild b/media-gfx/gmic/gmic-1.5.2.5.ebuild
new file mode 100644
index 000000000000..3c692c965c35
--- /dev/null
+++ b/media-gfx/gmic/gmic-1.5.2.5.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/gmic-1.5.2.5.ebuild,v 1.1 2013/01/09 03:05:09 radhermit Exp $
+
+EAPI="5"
+
+inherit eutils toolchain-funcs bash-completion-r1 flag-o-matic
+
+DESCRIPTION="GREYC's Magic Image Converter"
+HOMEPAGE="http://gmic.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.tar.gz
+	doc? ( http://dev.gentoo.org/~radhermit/dist/gmic_reference-${PV}.pdf.xz )"
+
+LICENSE="CeCILL-2 FDL-1.3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ffmpeg fftw graphicsmagick jpeg opencv openexr png tiff X zlib"
+
+RDEPEND="
+	ffmpeg? ( virtual/ffmpeg )
+	fftw? ( sci-libs/fftw:3.0 )
+	graphicsmagick? ( media-gfx/graphicsmagick )
+	jpeg? ( virtual/jpeg )
+	opencv? ( >=media-libs/opencv-2.3.1a-r1 )
+	openexr? (
+		media-libs/ilmbase
+		media-libs/openexr
+	)
+	png? ( media-libs/libpng )
+	tiff? ( media-libs/tiff )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	doc? ( app-arch/xz-utils )"
+
+S=${WORKDIR}/${P}/src
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.5.2.2-makefile.patch
+	epatch "${FILESDIR}"/${PN}-1.5.2.2-ffmpeg.patch
+
+	for i in ffmpeg fftw jpeg opencv png tiff zlib ; do
+		use $i || { sed -i -r "s/^(${i}_(C|LD)FLAGS =).*/\1/I" Makefile || die ; }
+	done
+
+	use graphicsmagick || { sed -i -r "s/^(MAGICK_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
+	use openexr || { sed -i -r "s/^(EXR_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
+
+	if ! use X ; then
+		sed -i -r "s/^((X11|XSHM)_(C|LD)FLAGS =).*/\1/" Makefile || die
+
+		# Disable display capabilities when X support is disabled
+		append-cppflags -Dcimg_display=0
+	fi
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCXX)" CFLAGS="${CXXFLAGS} ${CPPFLAGS}" custom lib
+}
+
+src_install() {
+	dobin gmic
+	newlib.so libgmic.so libgmic.so.1
+
+	insinto /usr/include
+	doins gmic.h
+
+	doman ../man/gmic.1.gz
+	dodoc ../README
+
+	use doc && dodoc "${WORKDIR}"/gmic_reference-${PV}.pdf
+
+	newbashcomp gmic_bashcompletion.sh ${PN}
+}