Version bump

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

2 files changed, 81 insertions, 1 deletions

diff --git a/media-libs/libmediainfo/ChangeLog b/media-libs/libmediainfo/ChangeLog
index a9a1e756464b..3449867eff6e 100644
--- a/media-libs/libmediainfo/ChangeLog
+++ b/media-libs/libmediainfo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libmediainfo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.22 2011/07/21 23:14:57 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.23 2011/08/17 05:14:32 radhermit Exp $
+
+*libmediainfo-0.7.48 (17 Aug 2011)
+
+  17 Aug 2011; Tim Harder <radhermit@gentoo.org> +libmediainfo-0.7.48.ebuild:
+  Version bump
 
   21 Jul 2011; Tim Harder <radhermit@gentoo.org> -libmediainfo-0.7.41.ebuild,
   -files/libmediainfo-0.7.41-curl.patch:
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.48.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.48.ebuild
new file mode 100644
index 000000000000..2341c9f65ccc
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-0.7.48.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.48.ebuild,v 1.1 2011/08/17 05:14:32 radhermit Exp $
+
+EAPI="4"
+
+inherit autotools multilib flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="http://mediainfo.sourceforge.net/"
+SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	>=media-libs/libzen-0.4.20[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${MY_PN}Lib/Project/GNU/Library"
+
+src_prepare() {
+	# Don't force -O2 by default
+	sed -i -e "s:-O2::" configure.ac
+
+	append-flags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	default
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins "${S}"/${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+	if use doc; then
+		dohtml -r "${WORKDIR}"/${MY_PN}Lib/Doc/*
+	fi
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}