Version bump. Remove rapper (with it's manpage) from 1.4.21 for slotting.

(Portage version: 2.2_rc96/cvs/Linux x86_64)

4 files changed, 145 insertions, 2 deletions

diff --git a/media-libs/raptor/ChangeLog b/media-libs/raptor/ChangeLog
index c426dc139689..4fa83e37ec23 100644
--- a/media-libs/raptor/ChangeLog
+++ b/media-libs/raptor/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/raptor
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.84 2010/08/23 19:11:25 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.85 2010/10/15 18:15:29 ssuominen Exp $
+
+*raptor-1.9.0 (15 Oct 2010)
+*raptor-1.4.21-r1 (15 Oct 2010)
+
+  15 Oct 2010; Samuli Suominen <ssuominen@gentoo.org>
+  +raptor-1.4.21-r1.ebuild, +raptor-1.9.0.ebuild:
+  Version bump. Remove rapper (with it's manpage) from 1.4.21 for slotting.
 
   23 Aug 2010; Samuli Suominen <ssuominen@gentoo.org> raptor-1.4.21.ebuild:
   Punt .la files and fix HTML documentation directory.
diff --git a/media-libs/raptor/metadata.xml b/media-libs/raptor/metadata.xml
index e1774e3d9ad7..20b42e75e861 100644
--- a/media-libs/raptor/metadata.xml
+++ b/media-libs/raptor/metadata.xml
@@ -1,5 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sound</herd>
+  <herd>sound</herd>
+  <use>
+    <flag name="json">Enable support for JSON parsing</flag>
+  </use>
 </pkgmetadata>
diff --git a/media-libs/raptor/raptor-1.4.21-r1.ebuild b/media-libs/raptor/raptor-1.4.21-r1.ebuild
new file mode 100644
index 000000000000..36cdc27d9f68
--- /dev/null
+++ b/media-libs/raptor/raptor-1.4.21-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/raptor-1.4.21-r1.ebuild,v 1.1 2010/10/15 18:15:29 ssuominen Exp $
+
+EAPI=3
+inherit eutils libtool
+
+DESCRIPTION="The RDF Parser Toolkit"
+HOMEPAGE="http://librdf.org/raptor"
+SRC_URI="http://download.librdf.org/source/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+curl debug static-libs unicode +xml"
+
+RDEPEND="unicode? ( dev-libs/glib:2 )
+	xml? ( >=dev-libs/libxml2-2.6.8 )
+	!xml? ( dev-libs/expat )
+	curl? ( net-misc/curl )
+	dev-libs/libxslt"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	dev-util/pkgconfig"
+
+src_prepare() {
+	epunt_cxx
+	elibtoolize # Required by FreeBSD .so versioning
+}
+
+src_configure() {
+	local myconf
+
+	if use xml; then
+		myconf+=" --with-xml-parser=libxml"
+	else
+		myconf+=" --with-xml-parser=expat"
+	fi
+
+	if use curl; then
+		myconf+=" --with-www=curl"
+	elif use xml; then
+		myconf+=" --with-www=xml"
+	else
+		myconf+=" --with-www=none"
+	fi
+
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable static-libs static) \
+		$(use_enable unicode nfc-check) \
+		$(use_enable debug) \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS NOTICE README
+	dohtml NEWS.html README.html RELEASE.html
+	find "${ED}" -name '*.la' -exec rm -f '{}' +
+
+	# Fix file collision with SLOT="2"
+	rm -f "${D}"/usr/bin/rapper "${D}"/usr/share/man/man1/rapper.1*
+}
diff --git a/media-libs/raptor/raptor-1.9.0.ebuild b/media-libs/raptor/raptor-1.9.0.ebuild
new file mode 100644
index 000000000000..ad2786717042
--- /dev/null
+++ b/media-libs/raptor/raptor-1.9.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/raptor-1.9.0.ebuild,v 1.1 2010/10/15 18:15:29 ssuominen Exp $
+
+EAPI=3
+inherit eutils libtool
+
+MY_P=${PN}2-${PV}
+
+DESCRIPTION="The RDF Parser Toolkit"
+HOMEPAGE="http://librdf.org/raptor"
+SRC_URI="http://download.librdf.org/source/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1 Apache-2.0"
+SLOT="2"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+curl debug json static-libs unicode +xml"
+
+RDEPEND="unicode? ( dev-libs/glib:2 )
+	xml? ( >=dev-libs/libxml2-2.6.8 )
+	!xml? ( dev-libs/expat )
+	curl? ( net-misc/curl )
+	json? ( dev-libs/yajl )
+	dev-libs/libxslt"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epunt_cxx
+	elibtoolize # for FreeBSD
+}
+
+src_configure() {
+	local myconf
+
+	if use xml; then
+		myconf+=" --with-xml-parser=libxml"
+	else
+		myconf+=" --with-xml-parser=expat"
+	fi
+
+	if use curl; then
+		myconf+=" --with-www=curl"
+	elif use xml; then
+		myconf+=" --with-www=xml"
+	else
+		myconf+=" --with-www=none"
+	fi
+
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable static-libs static) \
+		$(use_enable unicode nfc-check) \
+		$(use_enable debug) \
+		$(use_with json yajl) \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS NOTICE README
+	dohtml {NEWS,README,RELEASE,UPGRADING}.html
+	find "${ED}" -name '*.la' -exec rm -f '{}' +
+}