convert to multilib

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

2 files changed, 81 insertions, 2 deletions

diff --git a/media-libs/smpeg/ChangeLog b/media-libs/smpeg/ChangeLog
index af9f92921bbc..837a2ba37fda 100644
--- a/media-libs/smpeg/ChangeLog
+++ b/media-libs/smpeg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/smpeg
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/smpeg/ChangeLog,v 1.61 2013/07/24 03:21:27 ottxor Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/smpeg/ChangeLog,v 1.62 2014/04/18 19:21:29 hasufell Exp $
+
+*smpeg-0.4.4-r10 (18 Apr 2014)
+
+  18 Apr 2014; Julian Ospald <hasufell@gentoo.org> +smpeg-0.4.4-r10.ebuild:
+  convert to multilib
 
   24 Jul 2013; Christoph Junghans <ottxor@gentoo.org> smpeg-0.4.4-r9.ebuild:
   added prefix support (bug #475970)
diff --git a/media-libs/smpeg/smpeg-0.4.4-r10.ebuild b/media-libs/smpeg/smpeg-0.4.4-r10.ebuild
new file mode 100644
index 000000000000..f0750f5afb33
--- /dev/null
+++ b/media-libs/smpeg/smpeg-0.4.4-r10.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/smpeg/smpeg-0.4.4-r10.ebuild,v 1.1 2014/04/18 19:21:29 hasufell Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs autotools flag-o-matic multilib-minimal
+
+DESCRIPTION="SDL MPEG Player Library"
+HOMEPAGE="http://icculus.org/smpeg/"
+SRC_URI="ftp://ftp.lokigames.com/pub/open-source/smpeg/${P}.tar.gz
+	mirror://gentoo/${P}-gtkm4.patch.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-solaris"
+IUSE="X debug mmx opengl static-libs"
+
+RDEPEND="
+	abi_x86_32? (
+		!app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
+		!<=app-emulation/emul-linux-x86-sdl-20140406
+	)
+	>=media-libs/libsdl-1.2.0[${MULTILIB_USEDEP}]
+	opengl? (
+		virtual/glu[${MULTILIB_USEDEP}]
+		virtual/opengl[${MULTILIB_USEDEP}]
+	)
+	X? (
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+	)"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES README README.SDL_mixer TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-m4.patch \
+		"${FILESDIR}"/${P}-gnu-stack.patch \
+		"${FILESDIR}"/${P}-config.patch \
+		"${FILESDIR}"/${P}-PIC.patch \
+		"${FILESDIR}"/${P}-gcc41.patch \
+		"${FILESDIR}"/${P}-flags.patch \
+		"${FILESDIR}"/${P}-automake.patch \
+		"${FILESDIR}"/${P}-mmx.patch \
+		"${FILESDIR}"/${P}-malloc.patch \
+		"${FILESDIR}"/${P}-missing-init.patch
+
+	cd "${WORKDIR}"
+	epatch "${DISTDIR}"/${P}-gtkm4.patch.bz2
+	rm "${S}/acinclude.m4"
+
+	cd "${S}"
+	AT_M4DIR="${S}/m4" eautoreconf
+}
+
+multilib_src_configure() {
+	[[ ${CHOST} == *-solaris* ]] && append-libs -lnsl -lsocket
+
+	# the debug option is bogus ... all it does is add extra
+	# optimizations if you pass --disable-debug
+	ECONF_SOURCE="${S}" econf \
+		--enable-debug \
+		--disable-gtk-player \
+		$(use_enable static-libs static) \
+		$(use_enable debug assertions) \
+		$(use_with X x) \
+		$(use_enable opengl opengl-player) \
+		$(use_enable mmx)
+}
+
+multilib_src_install_all() {
+	use static-libs || find "${ED}" -name '*.la' -exec rm -f {} +
+}