Add multilib support

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

3 files changed, 59 insertions, 18 deletions

diff --git a/media-libs/vo-amrwbenc/ChangeLog b/media-libs/vo-amrwbenc/ChangeLog
index a2a35a17688d..ed2da487b1fb 100644
--- a/media-libs/vo-amrwbenc/ChangeLog
+++ b/media-libs/vo-amrwbenc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/vo-amrwbenc
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/vo-amrwbenc/ChangeLog,v 1.25 2012/11/16 19:58:21 ago Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/vo-amrwbenc/ChangeLog,v 1.26 2013/05/08 09:09:52 aballier Exp $
+
+*vo-amrwbenc-0.1.2-r1 (08 May 2013)
+
+  08 May 2013; Alexis Ballier <aballier@gentoo.org>
+  +vo-amrwbenc-0.1.2-r1.ebuild, vo-amrwbenc-9999.ebuild:
+  Add multilib support
 
   16 Nov 2012; Agostino Sarubbo <ago@gentoo.org> vo-amrwbenc-0.1.0.ebuild,
   vo-amrwbenc-0.1.1.ebuild, vo-amrwbenc-0.1.2.ebuild:
diff --git a/media-libs/vo-amrwbenc/vo-amrwbenc-0.1.2-r1.ebuild b/media-libs/vo-amrwbenc/vo-amrwbenc-0.1.2-r1.ebuild
new file mode 100644
index 000000000000..22daef84a41c
--- /dev/null
+++ b/media-libs/vo-amrwbenc/vo-amrwbenc-0.1.2-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/vo-amrwbenc/vo-amrwbenc-0.1.2-r1.ebuild,v 1.1 2013/05/08 09:09:52 aballier Exp $
+
+EAPI=5
+
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
+
+if [[ ${PV} == *9999 ]] ; then
+	SCM="git-2"
+	EGIT_REPO_URI="git://github.com/mstorsjo/${PN}.git"
+	[[ ${PV%9999} != "" ]] && EGIT_BRANCH="release/${PV%.9999}"
+	AUTOTOOLS_AUTORECONF=1
+fi
+
+inherit autotools-multilib ${SCM}
+
+DESCRIPTION="VisualOn AMR-WB encoder library"
+HOMEPAGE="http://sourceforge.net/projects/opencore-amr/"
+
+if [[ ${PV} == *9999 ]] ; then
+	SRC_URI=""
+elif [[ ${PV%_p*} != ${PV} ]] ; then # Gentoo snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.xz"
+else # Official release
+	SRC_URI="mirror://sourceforge/opencore-amr/${P}.tar.gz"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+[[ ${PV} == *9999 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
+IUSE="examples static-libs"
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable examples example) \
+	)
+	autotools-multilib_src_configure
+}
diff --git a/media-libs/vo-amrwbenc/vo-amrwbenc-9999.ebuild b/media-libs/vo-amrwbenc/vo-amrwbenc-9999.ebuild
index 7a83e55de86b..9f0d6a2fcadc 100644
--- a/media-libs/vo-amrwbenc/vo-amrwbenc-9999.ebuild
+++ b/media-libs/vo-amrwbenc/vo-amrwbenc-9999.ebuild
@@ -1,16 +1,19 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/vo-amrwbenc/vo-amrwbenc-9999.ebuild,v 1.5 2012/05/15 13:09:37 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/vo-amrwbenc/vo-amrwbenc-9999.ebuild,v 1.6 2013/05/08 09:09:52 aballier Exp $
 
-EAPI=4
+EAPI=5
+
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
 
 if [[ ${PV} == *9999 ]] ; then
 	SCM="git-2"
 	EGIT_REPO_URI="git://github.com/mstorsjo/${PN}.git"
 	[[ ${PV%9999} != "" ]] && EGIT_BRANCH="release/${PV%.9999}"
+	AUTOTOOLS_AUTORECONF=1
 fi
 
-inherit eutils multilib autotools ${SCM}
+inherit autotools-multilib ${SCM}
 
 DESCRIPTION="VisualOn AMR-WB encoder library"
 HOMEPAGE="http://sourceforge.net/projects/opencore-amr/"
@@ -30,18 +33,9 @@ SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
 IUSE="examples static-libs"
 
-src_prepare() {
-	[[ ${PV} == *9999 ]] && eautoreconf
-}
-
 src_configure() {
-	econf \
-		--disable-dependency-tracking \
+	local myeconfargs=(
 		$(use_enable examples example) \
-		$(use_enable static-libs static)
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die
-	find "${D}"usr/$(get_libdir) -name '*.la' -delete
+	)
+	autotools-multilib_src_configure
 }