Version bump

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 981CA6FC)

4 files changed, 155 insertions, 1 deletions

diff --git a/media-libs/libpng/ChangeLog b/media-libs/libpng/ChangeLog
index 4a0a22b3edee..ede3e1eb7044 100644
--- a/media-libs/libpng/ChangeLog
+++ b/media-libs/libpng/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/libpng
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.490 2015/04/15 11:32:16 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.491 2015/08/03 09:03:40 polynomial-c Exp $
+
+*libpng-1.6.18 (03 Aug 2015)
+*libpng-1.5.23 (03 Aug 2015)
+*libpng-1.2.53 (03 Aug 2015)
+
+  03 Aug 2015; Lars Wendler <polynomial-c@gentoo.org> +libpng-1.2.53.ebuild,
+  +libpng-1.5.23.ebuild, +libpng-1.6.18.ebuild:
+  Version bump.
 
 *libpng-1.6.17 (15 Apr 2015)
 
diff --git a/media-libs/libpng/libpng-1.2.53.ebuild b/media-libs/libpng/libpng-1.2.53.ebuild
new file mode 100644
index 000000000000..14185b73d606
--- /dev/null
+++ b/media-libs/libpng/libpng-1.2.53.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.2.53.ebuild,v 1.1 2015/08/03 09:03:40 polynomial-c Exp $
+
+EAPI=5
+
+# this ebuild is only for the libpng12.so.0 SONAME for ABI compat
+
+inherit libtool multilib-minimal
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="libpng"
+SLOT="1.2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
+	!=media-libs/libpng-1.2*:0
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r3
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+DOCS=""
+
+src_prepare() {
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} econf --disable-static
+}
+
+multilib_src_compile() {
+	emake libpng12.la
+}
+
+multilib_src_install() {
+	newlib.so .libs/libpng12.so.0.* libpng12.so.0
+}
diff --git a/media-libs/libpng/libpng-1.5.23.ebuild b/media-libs/libpng/libpng-1.5.23.ebuild
new file mode 100644
index 000000000000..f5a3444ef027
--- /dev/null
+++ b/media-libs/libpng/libpng-1.5.23.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.5.23.ebuild,v 1.1 2015/08/03 09:03:40 polynomial-c Exp $
+
+EAPI=5
+
+# this ebuild is only for the libpng15.so.15 SONAME for ABI compat
+
+inherit eutils libtool multilib-minimal
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
+
+LICENSE="libpng"
+SLOT="1.5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng neon"
+
+RDEPEND="sys-libs/zlib:=[${MULTILIB_USEDEP}]
+	!=media-libs/libpng-1.5*:0
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20140406-r4
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+DOCS=""
+
+pkg_setup() {
+	local _preserved_lib=${EROOT}/usr/$(get_libdir)/libpng15.so.15
+	[[ -e ${_preserved_lib} ]] && rm -f "${_preserved_lib}"
+}
+
+src_prepare() {
+	if use apng; then
+		# fix windows path in patch file. Please check for each release if this can be removed again.
+		sed 's@scripts\\symbols.def@scripts/symbols.def@' \
+			-i "${WORKDIR}"/${PN}-*-apng.patch || die
+		epatch "${WORKDIR}"/${PN}-*-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		--disable-static \
+		--enable-arm-neon=$(usex neon)
+}
+
+multilib_src_compile() {
+	emake libpng15.la
+}
+
+multilib_src_install() {
+	newlib.so .libs/libpng15.so.15.* libpng15.so.15
+}
diff --git a/media-libs/libpng/libpng-1.6.18.ebuild b/media-libs/libpng/libpng-1.6.18.ebuild
new file mode 100644
index 000000000000..4a0abdcd4884
--- /dev/null
+++ b/media-libs/libpng/libpng-1.6.18.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.6.18.ebuild,v 1.1 2015/08/03 09:03:40 polynomial-c Exp $
+
+EAPI=5
+
+inherit eutils libtool multilib-minimal
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
+
+LICENSE="libpng"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng neon static-libs"
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r1
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+src_prepare() {
+	if use apng; then
+		epatch "${WORKDIR}"/${PN}-*-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable static-libs static) \
+		--enable-arm-neon=$(usex neon)
+}
+
+multilib_src_install_all() {
+	dodoc ANNOUNCE CHANGES libpng-manual.txt README TODO
+	prune_libtool_files --all
+}