Version bump

(Portage version: 2.1.9.41/cvs/Linux x86_64)

2 files changed, 89 insertions, 2 deletions

diff --git a/media-libs/libafterimage/ChangeLog b/media-libs/libafterimage/ChangeLog
index ecd18012f4da..9782b9e53376 100644
--- a/media-libs/libafterimage/ChangeLog
+++ b/media-libs/libafterimage/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libafterimage
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/ChangeLog,v 1.29 2010/11/11 10:08:26 ssuominen Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/ChangeLog,v 1.30 2011/02/28 17:47:15 bicatali Exp $
+
+*libafterimage-1.20 (28 Feb 2011)
+
+  28 Feb 2011; Sébastien Fabbro <bicatali@gentoo.org>
+  +libafterimage-1.20.ebuild:
+  Version bump
 
   11 Nov 2010; Samuli Suominen <ssuominen@gentoo.org>
   libafterimage-1.18-r1.ebuild:
diff --git a/media-libs/libafterimage/libafterimage-1.20.ebuild b/media-libs/libafterimage/libafterimage-1.20.ebuild
new file mode 100644
index 000000000000..10d84607e22b
--- /dev/null
+++ b/media-libs/libafterimage/libafterimage-1.20.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/libafterimage-1.20.ebuild,v 1.1 2011/02/28 17:47:15 bicatali Exp $
+
+EAPI=3
+inherit eutils
+
+MY_PN=libAfterImage
+
+DESCRIPTION="Afterstep's standalone generic image manipulation library"
+HOMEPAGE="http://www.afterstep.org/afterimage/index.php"
+SRC_URI="ftp://ftp.afterstep.org/stable/${MY_PN}/${MY_PN}-${PV}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="gif jpeg mmx nls png svg tiff examples static-libs truetype"
+
+RDEPEND="x11-libs/libSM
+	x11-libs/libXext
+	x11-libs/libXrender
+	png?  ( >=media-libs/libpng-1.4 )
+	jpeg? ( virtual/jpeg )
+	gif?  ( media-libs/giflib )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff )
+	truetype? ( media-libs/freetype )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	x11-proto/xextproto
+	!x11-wm/afterstep"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	# fix some ldconfig problem in makefile.in
+	epatch "${FILESDIR}"/${PN}-makefile.in.patch
+	# fix lib paths in afterimage-config
+	epatch "${FILESDIR}"/${PN}-config.patch
+	# remove forced flags
+	sed -i \
+		-e 's/CFLAGS="-O3"//' \
+		-e 's/ -rdynamic//' \
+		configure || die "sed failed"
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs staticlibs) \
+		$(use_enable nls i18n) \
+		$(use_enable mmx mmx-optimization) \
+		$(use_with png) \
+		$(use_with jpeg) \
+		$(use_with gif) \
+		$(use_with svg) \
+		$(use_with tiff) \
+		$(use_with truetype ttf) \
+		--enable-glx \
+		--enable-sharedlibs \
+		--with-x \
+		--with-xpm \
+		--without-builtin-gif \
+		--without-builtin-ungif \
+		--without-builtin-zlib \
+		--without-afterbase
+}
+
+src_install() {
+	emake \
+		DESTDIR="${ED}" \
+		AFTER_DOC_DIR="${ED}/usr/share/doc/${PF}" \
+		install || die "emake install failed"
+	dodoc ChangeLog README || die
+	if use examples; then
+		cd apps || die
+		emake clean
+		rm -f Makefile*
+		insinto /usr/share/doc/${PF}/examples
+		doins * || die "install examples failed"
+	fi
+}