Added desktop entry for ShmClient. Fixed quoting of PATCHES variable.

(Portage version: 2.1.5_rc6)

6 files changed, 156 insertions, 19 deletions

diff --git a/media-plugins/vdr-softdevice/ChangeLog b/media-plugins/vdr-softdevice/ChangeLog
index 6563c981a1da..783fcfb7cb40 100644
--- a/media-plugins/vdr-softdevice/ChangeLog
+++ b/media-plugins/vdr-softdevice/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-plugins/vdr-softdevice
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/ChangeLog,v 1.54 2008/04/18 20:34:54 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/ChangeLog,v 1.55 2008/04/24 19:21:52 zzam Exp $
+
+*vdr-softdevice-0.5.0-r1 (24 Apr 2008)
+
+  24 Apr 2008; Matthias Schwarzott <zzam@gentoo.org>
+  vdr-softdevice-0.4.0.ebuild, vdr-softdevice-0.4.0.20070711.ebuild,
+  vdr-softdevice-0.4.0.20070711-r1.ebuild,
+  vdr-softdevice-0.4.0.20080120.ebuild, +vdr-softdevice-0.5.0-r1.ebuild:
+  Added desktop entry for ShmClient. Fixed quoting of PATCHES variable.
 
 *vdr-softdevice-0.5.0 (18 Apr 2008)
 
diff --git a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711-r1.ebuild b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711-r1.ebuild
index 7ba310f710b2..e106ad7b8471 100644
--- a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711-r1.ebuild
+++ b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711-r1.ebuild,v 1.5 2008/01/20 21:54:37 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711-r1.ebuild,v 1.6 2008/04/24 19:21:52 zzam Exp $
 
 inherit vdr-plugin versionator
 
@@ -49,10 +49,9 @@ DEPEND="${RDEPEND}
 # Remove this once default-linux/amd64/2006.1 is deprecated
 DEPEND="${DEPEND} amd64? ( >=sys-apps/portage-2.1.2 )"
 
-PATCHES="
-		${FILESDIR}/patches-0.4.0/shm-fullscreen-parameter.diff
-		${FILESDIR}/patches-0.4.0/shm-init-setupStore.diff
-		${FILESDIR}/patches-0.4.0/stream-repacker.diff"
+PATCHES=("${FILESDIR}/patches-0.4.0/shm-fullscreen-parameter.diff"
+	"${FILESDIR}/patches-0.4.0/shm-init-setupStore.diff"
+	"${FILESDIR}/patches-0.4.0/stream-repacker.diff")
 
 pkg_setup() {
 	vdr-plugin_pkg_setup
diff --git a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711.ebuild b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711.ebuild
index 40d0aaae49da..4be132402636 100644
--- a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711.ebuild
+++ b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711.ebuild,v 1.4 2008/01/20 21:54:37 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20070711.ebuild,v 1.5 2008/04/24 19:21:52 zzam Exp $
 
 inherit vdr-plugin versionator
 
@@ -49,9 +49,8 @@ DEPEND="${RDEPEND}
 # Remove this once default-linux/amd64/2006.1 is deprecated
 DEPEND="${DEPEND} amd64? ( >=sys-apps/portage-2.1.2 )"
 
-PATCHES="
-		${FILESDIR}/patches-0.4.0/shm-fullscreen-parameter.diff
-		${FILESDIR}/patches-0.4.0/shm-init-setupStore.diff"
+PATCHES=("${FILESDIR}/patches-0.4.0/shm-fullscreen-parameter.diff"
+	"${FILESDIR}/patches-0.4.0/shm-init-setupStore.diff")
 
 pkg_setup() {
 	vdr-plugin_pkg_setup
diff --git a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20080120.ebuild b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20080120.ebuild
index 5772e3e7cd34..f213b0d4e1c3 100644
--- a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20080120.ebuild
+++ b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20080120.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20080120.ebuild,v 1.2 2008/01/20 21:54:37 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.20080120.ebuild,v 1.3 2008/04/24 19:21:52 zzam Exp $
 
 inherit vdr-plugin versionator
 
@@ -49,9 +49,8 @@ DEPEND="${RDEPEND}
 # Remove this once default-linux/amd64/2006.1 is deprecated
 DEPEND="${DEPEND} amd64? ( >=sys-apps/portage-2.1.2 )"
 
-PATCHES="
-		${FILESDIR}/patches-0.4.0/shm-fullscreen-parameter.diff
-		${FILESDIR}/patches-0.4.0/stream-repacker.diff"
+PATCHES=("${FILESDIR}/patches-0.4.0/shm-fullscreen-parameter.diff"
+	"${FILESDIR}/patches-0.4.0/stream-repacker.diff")
 
 pkg_setup() {
 	vdr-plugin_pkg_setup
diff --git a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild
index bd13c3243e04..b5d8439b07f0 100644
--- a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild
+++ b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild,v 1.6 2008/01/20 21:54:37 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild,v 1.7 2008/04/24 19:21:52 zzam Exp $
 
 inherit vdr-plugin versionator
 
@@ -49,10 +49,9 @@ DEPEND="${RDEPEND}
 # Remove this once default-linux/amd64/2006.1 is deprecated
 DEPEND="${DEPEND} amd64? ( >=sys-apps/portage-2.1.2 )"
 
-PATCHES="
-		${FILESDIR}/${PN}-0.2.3-shm-fullscreen.diff
-		${FILESDIR}/${PN}-0.4.0-xinerama-configure-opts.patch
-		${FILESDIR}/${PN}-0.3.1-osdmode-software-default.diff"
+PATCHES=("${FILESDIR}/${PN}-0.2.3-shm-fullscreen.diff"
+	"${FILESDIR}/${PN}-0.4.0-xinerama-configure-opts.patch"
+	"${FILESDIR}/${PN}-0.3.1-osdmode-software-default.diff")
 
 pkg_setup() {
 	vdr-plugin_pkg_setup
diff --git a/media-plugins/vdr-softdevice/vdr-softdevice-0.5.0-r1.ebuild b/media-plugins/vdr-softdevice/vdr-softdevice-0.5.0-r1.ebuild
new file mode 100644
index 000000000000..f3b0487ff170
--- /dev/null
+++ b/media-plugins/vdr-softdevice/vdr-softdevice-0.5.0-r1.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.5.0-r1.ebuild,v 1.1 2008/04/24 19:21:52 zzam Exp $
+
+inherit eutils vdr-plugin versionator
+
+DESCRIPTION="VDR Plugin: Software output-Device"
+HOMEPAGE="http://softdevice.berlios.de/"
+
+# Detect snapshots
+SNAP_V="$(get_version_component_range 4)"
+if [[ "$SNAP_V" ]]; then
+	MY_P="${PN}-cvs-${SNAP_V}"
+	S="${WORKDIR}/${MY_P#vdr-}"
+	SRC_URI="mirror://gentoo/${MY_P}.tar.bz2
+			http://dev.gentoo.org/~zzam/distfiles/${MY_P}.tar.bz2"
+else
+	SRC_URI="mirror://berlios/${PN#vdr-}/${P}.tgz"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="xv fbcon directfb mmx mmxext xinerama"
+
+RDEPEND=">=media-video/vdr-1.3.36
+	>=media-video/ffmpeg-0.4.9_pre1
+	directfb? (
+		dev-libs/DirectFB
+		dev-libs/DFB++
+	)
+	media-libs/alsa-lib
+	xv? ( x11-libs/libX11
+				x11-libs/libXext
+				x11-libs/libXi
+				x11-libs/libXv
+				xinerama? ( x11-libs/libXinerama )
+	)"
+
+DEPEND="${RDEPEND}
+	xv? ( x11-proto/xproto
+				x11-proto/xextproto
+				x11-libs/libXv
+				xinerama? ( x11-proto/xineramaproto )
+			)
+	fbcon? ( sys-kernel/linux-headers )
+	dev-util/pkgconfig"
+# Make sure the assembler USE flags are unmasked on amd64
+# Remove this once default-linux/amd64/2006.1 is deprecated
+DEPEND="${DEPEND} amd64? ( >=sys-apps/portage-2.1.2 )"
+
+PATCHES=("${FILESDIR}/patches-0.4.0/shm-fullscreen-parameter.diff")
+
+pkg_setup() {
+	vdr-plugin_pkg_setup
+
+	if use !xv && use !fbcon && use !directfb; then
+		ewarn "You need to set at least one of these use-flags: xv fbcon directfb"
+		die "no output-method enabled"
+	fi
+
+	COMPILE_SHM=0
+	if has_version ">=media-video/vdr-1.3.0"; then
+		if use xv; then
+			COMPILE_SHM=1
+		else
+			elog "SHM does only support xv at the moment"
+		fi
+	else
+		elog "SHM not supported on vdr-1.2"
+	fi
+	case ${COMPILE_SHM} in
+		0)	elog "SHM support will not be compiled." ;;
+		1)	elog "SHM support will be compiled." ;;
+	esac
+
+	# Check for ffmpeg relying on libtheora without pkg-config-file
+	# Bug #142250
+	if built_with_use media-video/ffmpeg theora	&& \
+		has_version "<media-libs/libtheora-1.0_alpha4"; then
+
+			eerror "This package will not work when using ffmpeg with"
+			eerror "USE=\"theora\" combined with media-libs/libtheora"
+			eerror "older than version 1.0_alpha4."
+			eerror "Please update to at least media-libs/libtheora-1.0_alpha4."
+			die "Please update to at least media-libs/libtheora-1.0_alpha4."
+	fi
+}
+
+src_compile() {
+	local MYOPTS=""
+	MYOPTS="${MYOPTS} --disable-vidix"
+	use xv || MYOPTS="${MYOPTS} --disable-xv"
+	use fbcon || MYOPTS="${MYOPTS} --disable-fb"
+	use directfb || MYOPTS="${MYOPTS} --disable-dfb"
+
+	use mmx || MYOPTS="${MYOPTS} --disable-mmx"
+	use mmxext || MYOPTS="${MYOPTS} --disable-mmx2"
+
+	if use !mmx && use !mmxext; then
+		ewarn "${PN}"' does not compile with USE="-mmx -mmxext".'
+		ewarn 'Please enable at least one of these two use-flags.'
+		die "${PN}"' does not compile with USE="-mmx -mmxext".'
+	fi
+
+	use xinerama || MYOPTS="${MYOPTS} --disable-xinerama"
+
+	[[ ${COMPILE_SHM} == 1 ]] || MYOPTS="${MYOPTS} --disable-shm"
+
+	cd "${S}"
+	elog configure ${MYOPTS}
+	./configure ${MYOPTS} || die "configure failed"
+
+	vdr-plugin_src_compile
+}
+
+src_install() {
+	vdr-plugin_src_install
+
+	cd "${S}"
+
+	insinto "${VDR_PLUGIN_DIR}"
+	doins libsoftdevice-*.so.*
+
+	if [[ "${COMPILE_SHM}" = "1" ]]; then
+		exeinto "/usr/bin"
+		doexe ShmClient
+		make_desktop_entry ShmClient "VDR softdevice Client" "" "AudioVideo;TV"
+	fi
+
+	insinto /usr/include/vdr-softdevice
+	doins *.h
+}